kde-apps/krdc: 22.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/kde-apps/krdc/Manifest b/kde-apps/krdc/Manifest
new file mode 100644
index 00000000000..7a46c18e15e
--- /dev/null
+++ b/kde-apps/krdc/Manifest
@@ -0,0 +1 @@
+DIST krdc-22.12.3.tar.xz 1633132 BLAKE2B 20212553dbc3b7021967e6cb380f412d87acbb3118d903249341ac44cf9c2f9f9b06fd37d8f25047cb15f499635bcfaf4fa2a83fa1486cb4a9850006b190d0c9 SHA512 6cfa7cb09d80ccb38fe0308f217cb8da15f015d78c4475c067d15cc64abbe43a161112c87b8e85a002c825101f0ac8f9df305a6113d431fc5e7ef86c5904f564
diff --git a/kde-apps/krdc/krdc-22.12.3.ebuild b/kde-apps/krdc/krdc-22.12.3.ebuild
new file mode 100644
index 00000000000..0bc86f19fd8
--- /dev/null
+++ b/kde-apps/krdc/krdc-22.12.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+KFMIN=5.101.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Remote desktop connection (RDP and VNC) client"
+HOMEPAGE="https://apps.kde.org/krdc/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="activities +rdp +vnc"
+
+#nx? ( >=net-misc/nxcl-0.9-r1 ) disabled upstream, last checked 2016-01-24
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdnssd-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	vnc? (
+		net-libs/libssh:=
+		>=net-libs/libvncserver-0.9
+	)
+"
+RDEPEND="${DEPEND}
+	rdp? ( >=net-misc/freerdp-1.1.0_beta1[X] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		-DWITH_RDP=$(usex rdp)
+		-DWITH_VNC=$(usex vnc)
+	)
+
+	ecm_src_configure
+}