kde-apps/dolphin-plugins-mercurial: 21.11.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-mercurial/Manifest b/kde-apps/dolphin-plugins-mercurial/Manifest
new file mode 100644
index 00000000000..34183de92d3
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-21.11.80.tar.xz 254744 BLAKE2B 7c2182a7b6b2060444b98aacaaf14e68040373b0f1691d25fd8f97344b7ac8ffb90345e0e3d7e817ccaf0ca00aca47f40c71da955182945223ee669b34c6f5e2 SHA512 0e166974eb363e9625dd21fcca615abd07c69b05719d019efd68f260e80dd37194bdc30932cafaa5ae2d57b64bde5043ad87178c9a2ac25b695dab600d7900c7
diff --git a/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.11.80.ebuild b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.11.80.ebuild
new file mode 100644
index 00000000000..d3fdb5cd4d8
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.11.80.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	dev-vcs/mercurial
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}