kde-apps/umbrello: 25.03.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
index fc85bb86162..a09e43cad43 100644
--- a/kde-apps/umbrello/Manifest
+++ b/kde-apps/umbrello/Manifest
@@ -1 +1,2 @@
 DIST umbrello-25.03.80.tar.xz 5617312 BLAKE2B 1830dc6ac72e37ddc9619f18ab9bd078352382d573e5f6b4be095fadfaff5708be9da45d504c1c39c3abb22c86f644b5fee926e0d47231655fc75e9a36d5cad0 SHA512 2e13d1271dd02e2c84775ef8e0d68452fcd01675bb53660be2087451e3afab20393b99e631cf7e84a776a1a282b3e3fcab8df7b543c9e57fb551852171888e8f
+DIST umbrello-25.03.90.tar.xz 5617208 BLAKE2B 69ec21490f8ff10c373e761163f48e0220ed4934d9a1724fbd305be52c14a1538f9911443f53428ead09ee51221414cfa30b68ea403fe6b91454717b75995056 SHA512 d9b03ce59d496b9881b82ca86caee5146e5cda304596873eea25db154796f3027d6d1a62608063da9cdb04156f42b834b15155dabf654ddbee82603df152c445
diff --git a/kde-apps/umbrello/umbrello-25.03.90.ebuild b/kde-apps/umbrello/umbrello-25.03.90.ebuild
new file mode 100644
index 00000000000..6b979d0a9bb
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-25.03.90.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.115.0
+QTMIN=5.15.12
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+# TODO: Re-enable when ported to KF6
+# IUSE="php"
+# 	php? (
+# 		dev-util/kdevelop:5=
+# 		dev-util/kdevelop-pg-qt:5
+# 		dev-util/kdevelop-php:5
+# 	)
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-24.11.80-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DBUILD_APIDOC=OFF
+		-DBUILD_PHP_IMPORT=OFF # $(usex php)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}