kde-apps/kmix: 23.04.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-apps/kmix/Manifest b/kde-apps/kmix/Manifest
new file mode 100644
index 00000000000..17626b58e6b
--- /dev/null
+++ b/kde-apps/kmix/Manifest
@@ -0,0 +1 @@
+DIST kmix-23.04.1.tar.xz 1196772 BLAKE2B 203999cd8709be1a4690ea0a03e58aea0cadb4944b5b8443fce282747bb8dbf45079dd2a6ce96f3702584e0888332d7f047c756debef794177c9082dfefe351c SHA512 f3acf43b8d63f43940f08e30aa4e37db42075c2e2765c79c8a647b102013a9e9b48358dc9cb76d21de84857c4cc481b209d0a39d28f9a336c5da01d474bad26b
diff --git a/kde-apps/kmix/kmix-23.04.1.ebuild b/kde-apps/kmix/kmix-23.04.1.ebuild
new file mode 100644
index 00000000000..507a2af353b
--- /dev/null
+++ b/kde-apps/kmix/kmix-23.04.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="false"
+KFMIN=5.104.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Volume control gui based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kmix/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa plasma pulseaudio"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	alsa? ( >=media-libs/alsa-lib-1.0.14a )
+	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
+	pulseaudio? (
+		media-libs/libcanberra
+		media-libs/libpulse
+	)
+"
+RDEPEND="${DEPEND}
+	kde-plasma/kde-cli-tools:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package alsa ALSA)
+		-DBUILD_DATAENGINE=$(usex plasma)
+		$(cmake_use_find_package pulseaudio Canberra)
+		$(cmake_use_find_package pulseaudio PulseAudio)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if use pulseaudio && has_version kde-plasma/plasma-pa; then
+		elog "In KDE Plasma, kde-plasma/plasma-pa is the default audio volume handler."
+		elog "Should you prefer this to be kde-apps/kmix instead, do the following:"
+		elog " - In system tray, right click on [Show hidden items]"
+		elog " - Select [Configure System Tray]"
+		elog " - In [Entries],  search for [Audio Volume] and set it to [Disabled]"
+		elog "KMix will be shown as [Volume Control]."
+	fi
+	ecm_pkg_postinst
+}