kde-apps/dolphin-plugins-mercurial: 22.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-mercurial/Manifest b/kde-apps/dolphin-plugins-mercurial/Manifest
new file mode 100644
index 00000000000..eaf06456d59
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-22.08.3.tar.xz 260088 BLAKE2B 2927d42a603776cc3b600606ff2f27a77c8bbbe6b089d3e691571c7594d0e4d53023064afbf07e02f546073823a873fd45f200ea13b9e2765b61046602d8239b SHA512 2201858d9d349c28cced78dcfd9a31c3fde05b3ab107a28615af4cc5c32d4315074881f78dfb255638a13269de16ab68b7c53b68d013cf46ded091f8b059173e
diff --git a/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.08.3.ebuild b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.08.3.ebuild
new file mode 100644
index 00000000000..4ab8eae7609
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.08.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	dev-vcs/mercurial
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}