kde-misc/kweather: 23.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/kde-misc/kweather/Manifest b/kde-misc/kweather/Manifest
new file mode 100644
index 00000000000..8d387a7af8a
--- /dev/null
+++ b/kde-misc/kweather/Manifest
@@ -0,0 +1 @@
+DIST kweather-23.08.3.tar.xz 946512 BLAKE2B b4732429e4ce1cfa581b7626ae347d5b532528f45e8834bc6413f9d62a98f1c791361a9ff8f5ecce9dff9878c3e673c28dab0e84e4aa804812e8f0b20fc90221 SHA512 21df82a737ba155115a35327831eaf81911119260492efaa80a2df609d1da0494370df6fa2fc06cc1c20e594e998e30212467613a5166268ab3058cb815bac64
diff --git a/kde-misc/kweather/kweather-23.08.3.ebuild b/kde-misc/kweather/kweather-23.08.3.ebuild
new file mode 100644
index 00000000000..1fea67873b1
--- /dev/null
+++ b/kde-misc/kweather/kweather-23.08.3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="utilities"
+ECM_TEST="false"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Weather forecast application for Plasma with flat and dynamic/animated views"
+HOMEPAGE="https://apps.kde.org/kweather/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~x86"
+
+DEPEND="
+	>=dev-libs/kirigami-addons-0.6:5
+	>=dev-libs/kweathercore-0.6:5
+	>=dev-qt/qtcharts-${QTMIN}:5[qml]
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpositioning-${QTMIN}:5[geoclue]
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	sed -e "/include(ECMCheckOutboundLicense)/s/^/#DONT /" \
+		-e "/ecm_check_outbound_license/s/^/#DONT /" \
+		-i CMakeLists.txt || die # avoid cmake spam about python, reusetool
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PLASMOID=ON
+	)
+	ecm_src_configure
+}