kde-apps/ark: drop 25.07.90

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 81 deletions

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index b9a79aa4b96..b198c31817f 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1,2 +1 @@
-DIST ark-25.07.90.tar.xz 3017152 BLAKE2B 71e22c83828e7f4bb744b111653abb2895a753b512b89312710bd30887dbaeeff78e19dc7c00a378f00cfb40795e03cb040a5cdedea5dde2bb263af13c81858f SHA512 a1c7e5e570e7c6432c992f2d3a5fd4df2f4d7485b31f1799cae2fbc1b796b1451f46ad32450a87af42155f519acab48dd93661d1e1aea99c6aeaabfd0f2c73ee
 DIST ark-25.08.0.tar.xz 3017172 BLAKE2B 1aa532602d1b0c4c051a8197e3a64e0a69254ebf04a736e947f8384d8002d1307d4ff872ac3afa1815c055dba23b6b93f16f5d56c5fdab2be3db83d1e20cea7d SHA512 a09c23734d7e0512cfec142f86c8109215b1238c798430104555d07ed48bce4b16d5aac2beba420f9a266537b1ab8f580bf230094b2e3612c9f6eecd041b55d6
diff --git a/kde-apps/ark/ark-25.07.90.ebuild b/kde-apps/ark/ark-25.07.90.ebuild
deleted file mode 100644
index c4efae7209b..00000000000
--- a/kde-apps/ark/ark-25.07.90.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KFMIN=6.16.0
-QTMIN=6.9.1
-inherit ecm gear.kde.org optfeature xdg
-
-DESCRIPTION="File archiver by KDE"
-HOMEPAGE="https://apps.kde.org/ark/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="zip"
-
-RDEPEND="
-	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
-	>=kde-frameworks/kcompletion-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/kdbusaddons-${KFMIN}:6
-	>=kde-frameworks/kfilemetadata-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/kjobwidgets-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/kpty-${KFMIN}:6
-	>=kde-frameworks/kservice-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kwindowsystem-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	sys-libs/zlib
-	zip? ( >=dev-libs/libzip-1.6.0:= )
-"
-DEPEND="${RDEPEND}
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
-	test? ( >=dev-libs/libzip-1.6.0:= )
-"
-# app-arch/rar is binary only
-BDEPEND="
-	sys-devel/gettext
-	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package zip LibZip)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	local myctestargs=(
-		# bug 822177: kerfuffle-addtoarchivetest: may segfault or hang indefinitely
-		# bug 827840: plugins-clirartest: continuously broken with translations installed
-		-E "(kerfuffle-addtoarchivetest|plugins-clirartest)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "rar archive creation/extraction" "app-arch/rar"
-		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
-		optfeature "7-Zip archive support" ">=app-arch/7zip-24.09[symlink(+)]" "app-arch/p7zip"
-		optfeature "lrz archive support" "app-arch/lrzip"
-		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
-	fi
-	xdg_pkg_postinst
-}