kde-frameworks/kwallet-runtime: drop 6.20.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 78 deletions

diff --git a/kde-frameworks/kwallet-runtime/Manifest b/kde-frameworks/kwallet-runtime/Manifest
deleted file mode 100644
index 313f0cb3306..00000000000
--- a/kde-frameworks/kwallet-runtime/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST kwallet-6.20.0.tar.xz 364444 BLAKE2B 48da4d34f248dc5d4279118e68111705957ce2e15491d2f6bd041db88e5ef0ba4f8d34eb3700b8648aec6179889756ca678844a390aef43030bcffba6f3d2ebc SHA512 71ccab5411a808f605c289df77cb09ce771104f3dfc17507d6216051fd3175d616fdf38a3ba1ea925317442c64874dd8c21fb8cb49414043dfacb4237ab9211f
diff --git a/kde-frameworks/kwallet-runtime/kwallet-runtime-6.20.0.ebuild b/kde-frameworks/kwallet-runtime/kwallet-runtime-6.20.0.ebuild
deleted file mode 100644
index e72d9c3a966..00000000000
--- a/kde-frameworks/kwallet-runtime/kwallet-runtime-6.20.0.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-KDE_ORG_NAME="kwallet"
-QTMIN=6.8.1
-inherit ecm frameworks.kde.org optfeature
-
-DESCRIPTION="Framework providing desktop-wide storage for passwords"
-
-LICENSE="LGPL-2+"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="gpg +man +keyring +legacy-kwallet X"
-
-DEPEND="
-	dev-libs/libgcrypt:0=
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
-	=kde-frameworks/kcolorscheme-${KDE_CATV}*:6
-	=kde-frameworks/kconfig-${KDE_CATV}*:6
-	=kde-frameworks/kcoreaddons-${KDE_CATV}*:6
-	=kde-frameworks/kcrash-${KDE_CATV}*:6
-	=kde-frameworks/kdbusaddons-${KDE_CATV}*:6
-	=kde-frameworks/ki18n-${KDE_CATV}*:6
-	=kde-frameworks/knotifications-${KDE_CATV}*:6
-	=kde-frameworks/kservice-${KDE_CATV}*:6
-	=kde-frameworks/kwallet-${KDE_CATV}*:6
-	=kde-frameworks/kwidgetsaddons-${KDE_CATV}*:6
-	=kde-frameworks/kwindowsystem-${KDE_CATV}*:6[X?]
-	gpg? ( dev-libs/qgpgme:= )
-	keyring? ( >=app-crypt/qca-2.3.9:2[qt6(+)] )
-	legacy-kwallet? ( app-crypt/libsecret )
-"
-RDEPEND="${DEPEND}
-	!<kde-frameworks/kwallet-5.116.0-r2:5[-kf6compat(-)]
-	!<kde-frameworks/kwallet-6.14.0:6
-	keyring? ( =kde-frameworks/ksecretd-services-${KDE_CATV}* )
-"
-BDEPEND="man? ( >=kde-frameworks/kdoctools-${KDE_CATV}:6 )"
-
-PATCHES=( "${FILESDIR}/${PN}-6.14.0-stdalone.patch" )
-
-src_prepare() {
-	ecm_src_prepare
-	cmake_comment_add_subdirectory -f src api
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_KWALLET_QUERY=ON # could be split easily together w/ docs
-		$(cmake_use_find_package gpg Gpgmepp)
-		-DBUILD_KSECRETD=$(usex keyring)
-		-DBUILD_KWALLETD=$(usex legacy-kwallet)
-		$(cmake_use_find_package man KF6DocTools)
-		-DWITH_X11=$(usex X)
-	)
-
-	ecm_src_configure
-}
-
-src_install() {
-	ecm_src_install
-
-	# provided by kde-frameworks/ksecretd-services
-	if use keyring; then
-		rm -v "${ED}"/usr/share/dbus-1/services/org.freedesktop.impl.portal.desktop.kwallet.service \
-			"${ED}"/usr/share/dbus-1/services/org.kde.secretservicecompat.service || die
-	fi
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Auto-unlocking after Plasma login" "kde-plasma/kwallet-pam"
-		optfeature "KWallet management" "kde-apps/kwalletmanager"
-		elog "For more information, read https://wiki.gentoo.org/wiki/KDE#KWallet"
-	fi
-}