app-cdr/dolphin-plugins-mountiso: 20.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
index a25c9e2591f..97bb950e8ab 100644
--- a/app-cdr/dolphin-plugins-mountiso/Manifest
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-20.11.80.tar.xz 236284 BLAKE2B 9973070f61bccf4426ced0f9c1c4cddac105f4de9312f684ad6c94441624a793e0d37d0c807cfb8ce6695445a080e85ed1b846ed40d513b2115005259534fb53 SHA512 4b59c73d77cf6c8fd39aa5c0db6c2bea386f805b6721a1e171ec91019fd99abb32bc55b73294d6138782896d194c5fb2ddc79d92f0072f47fa4d59112a484b40
+DIST dolphin-plugins-20.11.90.tar.xz 236296 BLAKE2B 35cc9d0b595232fa26dbf1f9815d30f7eb5fa7b95c0718ebd7ec2d2815447583e9dbe81254592948ce222ee6ba32d5f7c60ba1c14b3c288e1a9161207c6c6ffe SHA512 f766e276b67dade52611fdeb001dedfa64e6583db8615536e697acba05eddee31d0f344b100542918e6476223a73d5548fa4afeefcdbe6c275dd86aba4a1247f
diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-20.11.90.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-20.11.90.ebuild
new file mode 100644
index 00000000000..8382f72ba86
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-20.11.90.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_RELEASE_SERVICE="true"
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=5.75.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.1
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}