kde-frameworks/extra-cmake-modules: 5.85.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/kde-frameworks/extra-cmake-modules/Manifest b/kde-frameworks/extra-cmake-modules/Manifest
new file mode 100644
index 00000000000..8b57603765a
--- /dev/null
+++ b/kde-frameworks/extra-cmake-modules/Manifest
@@ -0,0 +1 @@
+DIST extra-cmake-modules-5.85.0.tar.xz 318048 BLAKE2B b33d1e4d131349f706f7ef3cc75b59dc48299f03c62699fb1cdc6a9c496ebc527628bf07da41241ddd86128c5fa44b2b2c0a68509a0eefe742efa37d02386be0 SHA512 78ff26496c37d93106449663ab30ad35784a3ad668f4b1ec49d1ef51916e5de050e828fec8f6dc4ee5e2bed95cf22becb06ddd971dc46b65acc19934f5c1c5b3
diff --git a/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.85.0.ebuild b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.85.0.ebuild
new file mode 100644
index 00000000000..13b356518d9
--- /dev/null
+++ b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.85.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+QTMIN=5.15.2
+inherit cmake kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT+=" !test? ( test )"
+
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qthelp-${QTMIN}:5
+	)
+	test? (
+		>=dev-qt/linguist-tools-${QTMIN}:5
+		>=dev-qt/qtcore-${QTMIN}:5
+	)
+"
+RDEPEND="
+	app-arch/libarchive[bzip2]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-5.72.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.74.0-disable-qmlplugindump.patch"
+)
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	# Requires PyQt5, bug #680256
+	sed -i -e "/^if(NOT SIP_Qt5Core_Mod_FILE)/s/NOT SIP_Qt5Core_Mod_FILE/TRUE/" \
+		tests/CMakeLists.txt || die "failed to disable GenerateSipBindings tests"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# ECMToolchainAndroidTest passes but then breaks src_install
+	# ECMPoQmToolsTest is broken, bug #627806
+	# KDEFetchTranslations can not possibly succeed in releases, bug #764953
+	# possible race condition with multiple jobs, bug #701854
+	local myctestargs=(
+		-j1
+		-E "(ECMToolchainAndroidTest|ECMPoQmToolsTest|KDEFetchTranslations)"
+	)
+
+	cmake_src_test
+}