kde-apps/ark: 22.07.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
new file mode 100644
index 00000000000..82fd5b16fbe
--- /dev/null
+++ b/kde-apps/ark/Manifest
@@ -0,0 +1 @@
+DIST ark-22.07.80.tar.xz 2782884 BLAKE2B a5f2f2393a30c25bc48c21a0e55284a62b856e516636851b87a9b0c129ac38db621c0c2715d4b7c3432493b02d9a6b4a95fcdbf0cae4796884cb0ec7852654d5 SHA512 6741d7ee427799550138f770c9505ca523a27b45c5cd3cd324d78947aba4a8fbc12b93193cd9b484366292046289e6877f2eb605ce359c5c32a723cb1489b489
diff --git a/kde-apps/ark/ark-22.07.80.ebuild b/kde-apps/ark/ark-22.07.80.ebuild
new file mode 100644
index 00000000000..9bd35d0c891
--- /dev/null
+++ b/kde-apps/ark/ark-22.07.80.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/ https://utils.kde.org/projects/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+	app-arch/libarchive:=[bzip2,lzma,zlib(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.6.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	test? ( >=dev-libs/libzip-1.6.0:= )
+"
+BDEPEND="
+	sys-devel/gettext
+	test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# bug 822177: may segfault or hang indefinitely
+		-E "(kerfuffle-addtoarchivetest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "rar archive creation/extraction" app-arch/rar
+		optfeature "rar archive extraction only" app-arch/unar app-arch/unrar
+		optfeature "7-Zip archive support" app-arch/p7zip
+		optfeature "lrz archive support" app-arch/lrzip
+		optfeature "markdown support in text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
+	fi
+	ecm_pkg_postinst
+}