kde-plasma: Add KDE Plasma 6.3 stable branch

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

67 files changed, 3636 insertions, 0 deletions

diff --git a/kde-plasma/bluedevil/bluedevil-6.3.49.9999.ebuild b/kde-plasma/bluedevil/bluedevil-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..022710a9c5d
--- /dev/null
+++ b/kde-plasma/bluedevil/bluedevil-6.3.49.9999.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+KFMIN=6.10.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="Bluetooth stack for KDE Plasma"
+HOMEPAGE="https://invent.kde.org/plasma/bluedevil"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS=""
+IUSE=""
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/bluez-qt-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ksvg-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+	>=kde-plasma/libplasma-${KDE_CATV}:6
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:6
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
diff --git a/kde-plasma/breeze-grub/breeze-grub-6.3.49.9999.ebuild b/kde-plasma/breeze-grub/breeze-grub-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..6aced6fe901
--- /dev/null
+++ b/kde-plasma/breeze-grub/breeze-grub-6.3.49.9999.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit plasma.kde.org
+
+DESCRIPTION="Breeze theme for GRUB"
+
+LICENSE="GPL-3+"
+SLOT="6"
+KEYWORDS=""
+IUSE=""
+
+src_prepare() { default; }
+src_configure() { :; }
+src_compile() { :; }
+
+src_install() {
+	insinto /usr/share/grub/themes
+	doins -r breeze
+}
diff --git a/kde-plasma/breeze-gtk/breeze-gtk-6.3.49.9999.ebuild b/kde-plasma/breeze-gtk/breeze-gtk-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..c692163dddb
--- /dev/null
+++ b/kde-plasma/breeze-gtk/breeze-gtk-6.3.49.9999.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=6.5.0
+PYTHON_COMPAT=( python3_{10..13} )
+inherit ecm plasma.kde.org python-any-r1
+
+DESCRIPTION="Official GTK+ port of Plasma's Breeze widget style"
+HOMEPAGE="https://invent.kde.org/plasma/breeze-gtk"
+
+LICENSE="LGPL-2.1+"
+SLOT="6"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	dev-lang/sassc
+	$(python_gen_any_dep 'dev-python/pycairo[${PYTHON_USEDEP}]')
+	>=kde-plasma/breeze-${KDE_CATV}:6
+"
+
+python_check_deps() {
+	python_has_version "dev-python/pycairo[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
diff --git a/kde-plasma/breeze-plymouth/breeze-plymouth-6.3.49.9999.ebuild b/kde-plasma/breeze-plymouth/breeze-plymouth-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..9448c65cadd
--- /dev/null
+++ b/kde-plasma/breeze-plymouth/breeze-plymouth-6.3.49.9999.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=6.10.0
+inherit cmake plasma.kde.org
+
+DESCRIPTION="Breeze theme for Plymouth"
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="6"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND=">=kde-frameworks/extra-cmake-modules-${KFMIN}:0"
+DEPEND="sys-boot/plymouth"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISTRO_NAME="Gentoo Linux"
+		-DDISTRO_VERSION=
+	)
+
+	cmake_src_configure
+}
diff --git a/kde-plasma/breeze/breeze-6.3.49.9999.ebuild b/kde-plasma/breeze/breeze-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..83504637f80
--- /dev/null
+++ b/kde-plasma/breeze/breeze-6.3.49.9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KF5MIN=5.115.0
+KFMIN=6.10.0
+QT5MIN=5.15.12
+QTMIN=6.8.1
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://invent.kde.org/plasma/breeze"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS=""
+IUSE="qt5"
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/frameworkintegration-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+	>=kde-plasma/kdecoration-${KDE_CATV}:6
+	qt5? (
+		>=dev-qt/qtdbus-${QT5MIN}:5
+		>=dev-qt/qtdeclarative-${QT5MIN}:5
+		>=dev-qt/qtgui-${QT5MIN}:5
+		>=dev-qt/qtwidgets-${QT5MIN}:5
+		>=dev-qt/qtx11extras-${QT5MIN}:5
+		>=kde-frameworks/frameworkintegration-${KF5MIN}:5
+		>=kde-frameworks/kcmutils-${KF5MIN}:5
+		>=kde-frameworks/kconfig-${KF5MIN}:5
+		>=kde-frameworks/kconfigwidgets-${KF5MIN}:5
+		>=kde-frameworks/kcoreaddons-${KF5MIN}:5
+		>=kde-frameworks/kguiaddons-${KF5MIN}:5
+		>=kde-frameworks/ki18n-${KF5MIN}:5
+		>=kde-frameworks/kiconthemes-${KF5MIN}:5
+		>=kde-frameworks/kirigami-${KF5MIN}:5
+		>=kde-frameworks/kwidgetsaddons-${KF5MIN}:5
+		>=kde-frameworks/kwindowsystem-${KF5MIN}:5
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	qt5? ( >=kde-frameworks/kcmutils-${KF5MIN}:5 )
+"
+PDEPEND=">=kde-frameworks/breeze-icons-${KFMIN}:*"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_QT6=ON
+		-DBUILD_QT5=$(usex qt5)
+	)
+	ecm_src_configure
+}
diff --git a/kde-plasma/discover/discover-6.3.49.9999.ebuild b/kde-plasma/discover/discover-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..f0f86a595e0
--- /dev/null
+++ b/kde-plasma/discover/discover-6.3.49.9999.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.10.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="KDE Plasma resources management GUI"
+HOMEPAGE="https://userbase.kde.org/Discover"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS=""
+IUSE="+firmware flatpak snap telemetry webengine"
+
+# libmarkdown (app-text/discount) only used in PackageKitBackend
+COMMON_DEPEND="
+	>=dev-libs/appstream-1.0.0:=[qt6]
+	dev-libs/kirigami-addons:6
+	>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/attica-${KFMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/purpose-${KFMIN}:6
+	firmware? ( >=sys-apps/fwupd-1.9.4 )
+	flatpak? ( sys-apps/flatpak )
+	snap? ( sys-libs/snapd-glib:=[qt6(-)] )
+	telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
+	webengine? ( >=dev-qt/qtwebview-${QTMIN}:6 )
+"
+RDEPEND="${COMMON_DEPEND}
+	snap? ( app-containers/snapd )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/qcoro
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+src_prepare() {
+	ecm_src_prepare
+	# we don't need it with PackageKitBackend off
+	ecm_punt_kf_module Archive
+	# we don't do anything with this
+	sed -e "s/^pkg_check_modules.*Markdown/#&/" \
+		-e "s/^pkg_check_modules.*RpmOstree/#&/" \
+		-e "s/^pkg_check_modules.*Ostree/#&/" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# TODO: Port PackageKit's portage back-end to python3
+		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt6=ON
+		# Automated updates will not work for us
+		# https://invent.kde.org/plasma/discover/-/merge_requests/142
+		-DWITH_KCM=OFF
+		-DBUILD_DummyBackend=OFF
+		-DBUILD_FlatpakBackend=$(usex flatpak)
+		-DBUILD_FwupdBackend=$(usex firmware)
+		-DBUILD_RpmOstreeBackend=OFF
+		-DBUILD_SnapBackend=$(usex snap)
+		-DBUILD_SteamOSBackend=OFF
+		$(cmake_use_find_package telemetry KF6UserFeedback)
+		$(cmake_use_find_package webengine Qt6WebView)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 686392: needs network connection
+	local myctestargs=(
+		-E "(knsbackendtest|flatpaktest)"
+	)
+
+	ecm_src_test
+}
diff --git a/kde-plasma/drkonqi/drkonqi-6.3.49.9999.ebuild b/kde-plasma/drkonqi/drkonqi-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..82c5f9c8399
--- /dev/null
+++ b/kde-plasma/drkonqi/drkonqi-6.3.49.9999.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{11..13} )
+KFMIN=6.10.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org python-single-r1 systemd xdg
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS=""
+IUSE="systemd"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test" # bug 935362
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
+	systemd? (
+		>=dev-qt/qtbase-${QTMIN}:6[network]
+		>=kde-frameworks/kservice-${KFMIN}:6
+		sys-apps/systemd:=
+		>=sys-auth/polkit-qt-0.175.0[qt6(+)]
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+	test? ( >=dev-qt/qtbase-${QTMIN}:6[network] )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	$(python_gen_cond_dep '
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygdbmi[${PYTHON_USEDEP}]
+	')
+	|| (
+		dev-debug/gdb
+		llvm-core/lldb
+	)
+"
+
+pkg_setup() {
+	ecm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_PYTHON_VENDORING=OFF
+		$(cmake_use_find_package systemd Systemd)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# needs network access, bug #698510
+	local myctestargs=(
+		-E "(connectiontest)"
+	)
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] && systemd_is_booted ; then
+		elog "For systemd, steps are needed for integration with systemd-coredumpd."
+		elog "As root, run the following:"
+		elog "1. systemctl enable drkonqi-coredump-processor@.service"
+		elog "2. systemctl --user enable --now --global drkonqi-coredump-launcher.socket"
+	fi
+}
diff --git a/kde-plasma/flatpak-kcm/flatpak-kcm-6.3.49.9999.ebuild b/kde-plasma/flatpak-kcm/flatpak-kcm-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..707b9f2a55b
--- /dev/null
+++ b/kde-plasma/flatpak-kcm/flatpak-kcm-6.3.49.9999.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=6.10.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="Flatpak Permissions Management KCM"
+HOMEPAGE="https://invent.kde.org/plasma/flatpak-kcm"
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="6"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	dev-libs/glib:2
+	>=dev-qt/qtbase-${QTMIN}:6
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdeclarative-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=sys-apps/flatpak-0.11.8
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:6
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
diff --git a/kde-plasma/kactivitymanagerd/kactivitymanagerd-6.3.49.9999.ebuild b/kde-plasma/kactivitymanagerd/kactivitymanagerd-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..cc7e957e641
--- /dev/null
+++ b/kde-plasma/kactivitymanagerd/kactivitymanagerd-6.3.49.9999.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=6.10.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="System service to manage user's activities, track the usage patterns etc."
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="6"
+KEYWORDS=""
+IUSE=""
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,sql,sqlite,widgets]
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
diff --git a/kde-plasma/kde-cli-tools-common/kde-cli-tools-common-6.3.49.9999.ebuild b/kde-plasma/kde-cli-tools-common/kde-cli-tools-common-6.3.49.9999.ebuild
new file mode 100644
index 00000000000..1cb2df50fd8
--- /dev/null
+++ b/kde-plasma/kde-cli-tools-common/kde-cli-tools-common-6.3.49.9999.ebuild
@@ -0,0 +1,14 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="true"
+KDE_ORG_NAME="${PN/-common/}"
+inherit ecm-common plasma.kde.org
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="0"
+KEYWORDS=""
+
+RDEPEND="!<${CATEGORY}/${KDE_ORG_NAME}-6.1.4-r2:*"
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-6.3.49.9999.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-6.3.49.9999.e