kde-apps/yakuake: 21.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/kde-apps/yakuake/Manifest b/kde-apps/yakuake/Manifest
new file mode 100644
index 00000000000..cf6b106dc1e
--- /dev/null
+++ b/kde-apps/yakuake/Manifest
@@ -0,0 +1 @@
+DIST yakuake-21.08.1.tar.xz 393208 BLAKE2B dbe1bf86f042ebeebe58ba28c348640bfb56b04bc48a7859b991a98f81087655f104ad51317271378e1cc5fb9f8151fda47d3b4ab882ee16806013cb70adcc19 SHA512 b1cc278960a74fe57a440b2b3dfe89cb58507600a1a09a325c5553026196177113ec14887c42b4c7e4a3991a7818c424df86a59eb0df09cb0edda7b20cb5f5ee
diff --git a/kde-apps/yakuake/yakuake-21.08.1.ebuild b/kde-apps/yakuake/yakuake-21.08.1.ebuild
new file mode 100644
index 00000000000..23d3773e089
--- /dev/null
+++ b/kde-apps/yakuake/yakuake-21.08.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.84.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Quake-style terminal emulator based on konsole"
+HOMEPAGE="https://apps.kde.org/yakuake/"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="absolute-position X"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/konsole-${PVCUT}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	absolute-position? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package absolute-position KF5Wayland)
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}