[app-office/akonadi-server] Bump to 1.11.0

Package-Manager: portage-2.2.7

2 files changed, 127 insertions, 0 deletions

diff --git a/app-office/akonadi-server/Manifest b/app-office/akonadi-server/Manifest
new file mode 100644
index 00000000000..7284e3dc1b4
--- /dev/null
+++ b/app-office/akonadi-server/Manifest
@@ -0,0 +1 @@
+DIST akonadi-server-1.11.0.tar.bz2 235101 SHA256 0cb257509d53927241b71d85c42efb0b5776efc37fc8dc732e75f6813b8a264d SHA512 366f0e4a86038af5eb6603653e599076c66e84f59db57f4c56a89ec265be7e335f3f5d14444030a6f398e2361969ad85bc73357359da7ab8c307ec3c5d80ea40 WHIRLPOOL b050f5e1d5220ec512ab6e57cd083b652f03ef1e391fb336a51888aede7b0faf2f2ab58db6f6e67ee3fd7ceea8efcb54d5c3b1a6c224adf3deb41cb10b3c91d2
diff --git a/app-office/akonadi-server/akonadi-server-1.11.0.ebuild b/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
new file mode 100644
index 00000000000..3d2cf0a6387
--- /dev/null
+++ b/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+if [[ $PV = *9999* ]]; then
+	scm_eclass=git-2
+	EGIT_REPO_URI="git://anongit.kde.org/akonadi"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://kde/stable/${PN/-server/}/src/${PN/-server/}-${PV}.tar.bz2 -> ${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${P/-server/}"
+fi
+
+inherit cmake-utils ${scm_eclass}
+
+DESCRIPTION="The server part of Akonadi"
+HOMEPAGE="http://pim.kde.org/akonadi"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+mysql postgres +qt4 qt5 sqlite test"
+
+REQUIRED_USE="^^ ( qt4 qt5 ) || ( sqlite mysql postgres )"
+
+CDEPEND="
+	dev-libs/boost:=
+	>=dev-libs/soprano-2.6.51
+	x11-misc/shared-mime-info
+	qt4? (
+		>=dev-qt/qtcore-4.8.5:4
+		>=dev-qt/qtdbus-4.8.5:4
+		>=dev-qt/qtgui-4.8.5:4
+		>=dev-qt/qtsql-4.8.5:4[mysql?,postgres?]
+		>=dev-qt/qttest-4.8.5:4
+	)
+	qt5? (
+		>=dev-libs/soprano-2.6.51[-qt4,qt5]
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsql:5[mysql?,postgres?]
+		dev-qt/qttest:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${CDEPEND}
+	dev-libs/libxslt
+	>=dev-util/automoc-0.9.88
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${CDEPEND}
+	postgres? ( dev-db/postgresql-server )
+"
+
+pkg_setup() {
+	# Set default storage backend in order: MySQL, SQLite PostgreSQL
+	# reverse driver check to keep the order
+	if use postgres; then
+		DRIVER="QPSQL"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	if use sqlite; then
+		DRIVER="QSQLITE3"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	if use mysql; then
+		DRIVER="QMYSQL"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	# Notify about MySQL is recommend by upstream
+	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
+		ewarn
+		ewarn "We strongly recommend you change your Akonadi database backend to MySQL in your"
+		ewarn "user configuration. This is the backend recommended by KDE upstream."
+		ewarn "In particular, kde-base/kmail-4.10 does not work properly with the sqlite"
+		ewarn "backend anymore."
+		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
+		ewarn "Available drivers are:${AVAILABLE}"
+		ewarn
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DAKONADI_USE_STRIGI_SEARCH=OFF
+		-DINSTALL_QSQLITE_IN_QT_PREFIX=ON
+		$(cmake-utils_use test AKONADI_BUILD_TESTS)
+		$(cmake-utils_use sqlite AKONADI_BUILD_QSQLITE)
+		$(cmake-utils_use qt5 QT5_BUILD)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	export $(dbus-launch)
+	cmake-utils_src_test
+}
+
+src_install() {
+	# Who knows, maybe it accidentally fixes our permission issues
+	cat <<-EOF > "${T}"/akonadiserverrc
+[%General]
+Driver=${DRIVER}
+EOF
+	insinto /usr/share/config/akonadi
+	doins "${T}"/akonadiserverrc
+
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	elog "${DRIVER} has been set as your default akonadi storage backend."
+	elog "You can override it in your ~/.config/akonadi/akonadiserverrc."
+	elog "Available drivers are: ${AVAILABLE}"
+}