kde-frameworks/extra-cmake-modules: 5.114.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/kde-frameworks/extra-cmake-modules/Manifest b/kde-frameworks/extra-cmake-modules/Manifest
new file mode 100644
index 00000000000..15f1a12a71e
--- /dev/null
+++ b/kde-frameworks/extra-cmake-modules/Manifest
@@ -0,0 +1 @@
+DIST extra-cmake-modules-5.114.0.tar.xz 332492 BLAKE2B 62da9786d39a33a649a2a85c1337a205b8e1bfe75e04f3a48456ba718cad43b752b604027d3d2fc1069dbd699180bf73629b366929b5eb375b1ab5541133295c SHA512 38431ab95a9648f2febe0d5a9e54a61a3a9d483f31ca1f410e2e9bdd4b4718ee501ec96c2b5097caa9facddf07b1f32671a510a4ccefa2d0791248684b3d934f
diff --git a/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.114.0.ebuild b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.114.0.ebuild
new file mode 100644
index 00000000000..b66b7a47adf
--- /dev/null
+++ b/kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.114.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+QTMIN=5.15.9
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/libarchive[bzip2]"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qthelp-${QTMIN}:5
+	)
+	test? (
+		>=dev-qt/linguist-tools-${QTMIN}:5
+		>=dev-qt/qtcore-${QTMIN}:5
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-5.93.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.93.0-disable-qmlplugindump.patch"
+	"${FILESDIR}/${PN}-5.112.0-disable-tests-requiring-PyQt5.patch" # bug 680256
+)
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# passes, but then breaks src_install
+		ECMToolchainAndroidTest
+		# broken, bug #627806
+		ECMPoQmToolsTest
+		# can not possibly succeed in releases, bug #764953
+		KDEFetchTranslations
+	)
+	# possible race condition with multiple jobs, bug #701854
+	cmake_src_test -j1
+}