kde-apps/kalzium: 22.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-apps/kalzium/Manifest b/kde-apps/kalzium/Manifest
new file mode 100644
index 00000000000..290813b91f6
--- /dev/null
+++ b/kde-apps/kalzium/Manifest
@@ -0,0 +1 @@
+DIST kalzium-22.08.1.tar.xz 24453900 BLAKE2B e38daab88ef35f6499ee254599d84f93ba89a33008a25500e650fcf2b93fdf259b2108141dbb79fe3910f67007dbab33481d2a475ec7a2312ee0376f9b910d0e SHA512 af9957cb5b5dffe071789ee0d059a06a9f7e04f0dd0146cdae1d7bb031992052959e67c503fda1aafabdfa967ff9136193273a95b16827d25e27d1a77d646f22
diff --git a/kde-apps/kalzium/kalzium-22.08.1.ebuild b/kde-apps/kalzium/kalzium-22.08.1.ebuild
new file mode 100644
index 00000000000..6dfdc82e809
--- /dev/null
+++ b/kde-apps/kalzium/kalzium-22.08.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org flag-o-matic
+
+DESCRIPTION="Periodic table of the elements"
+HOMEPAGE="https://apps.kde.org/kalzium/ https://edu.kde.org/kalzium/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="editor solver"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	editor? (
+		dev-cpp/eigen:3
+		>=dev-qt/qtopengl-${QTMIN}:5
+		>=kde-frameworks/knewstuff-${KFMIN}:5
+		sci-chemistry/openbabel:=
+		>=sci-libs/avogadrolibs-1.93[qt5]
+	)
+	solver? ( dev-ml/facile:=[ocamlopt] )
+"
+RDEPEND="${DEPEND}
+	sci-chemistry/chemical-mime-data
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.03.90-cmake.patch" )
+
+src_configure() {
+	# Fix missing finite()
+	[[ ${CHOST} == *-solaris* ]] && append-cppflags -DHAVE_IEEEFP_H
+
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_OpenBabel3=ON # TODO: bug 823101
+		$(cmake_use_find_package editor Eigen3)
+		$(cmake_use_find_package editor AvogadroLibs)
+		$(cmake_use_find_package editor OpenBabel2)
+		$(cmake_use_find_package solver OCaml)
+		$(cmake_use_find_package solver Libfacile)
+	)
+
+	ecm_src_configure
+}