kde-apps/umbrello: 24.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/kde-apps/umbrello/Manifest b/kde-apps/umbrello/Manifest
index 249f4fe37f1..c2aba28df62 100644
--- a/kde-apps/umbrello/Manifest
+++ b/kde-apps/umbrello/Manifest
@@ -1 +1,2 @@
 DIST umbrello-24.11.90.tar.xz 5617988 BLAKE2B 97b425874cf303ff53540977ca0dcf147eba172fe3779d5172e2784825e9798fea2b106990be25a1acc09543983950350672f301036b5df93171094dca08d8eb SHA512 8a5f25a59025bb30e2b130ac6a59890ab82a19651469edb4f35942f4790bffe5deee04ac6b24348fa6395c44f97941573523356bdcffab036f758d81a4261796
+DIST umbrello-24.12.0.tar.xz 5617524 BLAKE2B 664d40b4ea717e03f7c6b9a69d6d153117f8228fc562974619328dc398d187a9973ac88d023f39a24af7891ca867c293e3bf4cc97efc4878cba3f4cd75f5d136 SHA512 1dec0f3cd4b23099039b478393c9226c536592674e9a5596f890d1e5d7ab60c303179a074a43d9fea07c70525a1bc7ebefd1ace0b286956a20b339c84ab82294
diff --git a/kde-apps/umbrello/umbrello-24.12.0.ebuild b/kde-apps/umbrello/umbrello-24.12.0.ebuild
new file mode 100644
index 00000000000..b5b57681114
--- /dev/null
+++ b/kde-apps/umbrello/umbrello-24.12.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.115.0
+QTMIN=5.15.12
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+# TODO: Re-enable when ported to KF6
+# IUSE="php"
+# 	php? (
+# 		dev-util/kdevelop:5=
+# 		dev-util/kdevelop-pg-qt:5
+# 		dev-util/kdevelop-php:5
+# 	)
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-24.11.80-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DBUILD_APIDOC=OFF
+		-DBUILD_PHP_IMPORT=OFF # $(usex php)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}