kde-apps/kleopatra: 23.03.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-apps/kleopatra/Manifest b/kde-apps/kleopatra/Manifest
new file mode 100644
index 00000000000..2d9f6255546
--- /dev/null
+++ b/kde-apps/kleopatra/Manifest
@@ -0,0 +1 @@
+DIST kleopatra-23.03.80.tar.xz 2609504 BLAKE2B 72fa6441001dc82245646c41adc6f1e8832f9023488827e672a3fa5f9a4a23930b017852b78726f60f4e5ea54ad38cbaf660d97212c8c48eb3eaedadc76ac5ec SHA512 4846d311ca3e586efadfeffbfe47ed77560198efd859fd29971be5e85e3f1c68400d9210ea07b9c25cc0fbf86c52a9382d08970d80e911543ab868d87aff6d82
diff --git a/kde-apps/kleopatra/kleopatra-23.03.80.ebuild b/kde-apps/kleopatra/kleopatra-23.03.80.ebuild
new file mode 100644
index 00000000000..d56287dc11d
--- /dev/null
+++ b/kde-apps/kleopatra/kleopatra-23.03.80.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.104.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="Certificate manager and GUI for OpenPGP and CMS cryptography"
+HOMEPAGE="https://apps.kde.org/kleopatra/"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="pim"
+
+# tests completely broken, bug #641720
+RESTRICT="test"
+
+DEPEND="
+	>=app-crypt/gpgme-1.16.0:=[cxx,qt5]
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/libkleo-${PVCUT}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	pim? (
+		>=kde-apps/kidentitymanagement-${PVCUT}:5
+		>=kde-apps/kmailtransport-${PVCUT}:5
+	)
+"
+RDEPEND="${DEPEND}
+	>=app-crypt/gnupg-2.1
+	app-crypt/paperkey
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package pim KPim5IdentityManagement)
+		$(cmake_use_find_package pim KPim5MailTransport)
+		$(cmake_use_find_package pim KPim5MailTransportAkonadi)
+	)
+	ecm_src_configure
+}