kde-plasma/discover: drop 5.26.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 94 deletions

diff --git a/kde-plasma/discover/Manifest b/kde-plasma/discover/Manifest
deleted file mode 100644
index c2fd1493f26..00000000000
--- a/kde-plasma/discover/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST discover-5.26.0.tar.xz 652556 BLAKE2B 0fba44b54a60d1bf5c447a985085cdeba6e29ab4506447d2d0dd65f9a39d2bb8f2d2bd66b13d8f8dde04b33bad1002ed6f66518d7f9a02b78402dd458b44e4f2 SHA512 27bbd3f059f80365325490d702af6328149ae5f5f4e60d53708aeb2f8dea212c0b05fc5cba8ed7aa52a8ae71b6d2745f83cd153fb548ae391c3080f0117fc157
diff --git a/kde-plasma/discover/discover-5.26.0.ebuild b/kde-plasma/discover/discover-5.26.0.ebuild
deleted file mode 100644
index 0683ccee279..00000000000
--- a/kde-plasma/discover/discover-5.26.0.ebuild
+++ /dev/null
@@ -1,93 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_TEST="true"
-KFMIN=5.99.0
-QTMIN=5.15.5
-VIRTUALX_REQUIRED="test"
-inherit ecm plasma.kde.org
-
-DESCRIPTION="KDE Plasma resources management GUI"
-HOMEPAGE="https://userbase.kde.org/Discover"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="+firmware flatpak telemetry webengine"
-
-# libmarkdown (app-text/discount) only used in PackageKitBackend
-DEPEND="
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=kde-frameworks/attica-${KFMIN}:5
-	>=kde-frameworks/kcmutils-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kdeclarative-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kidletime-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kirigami-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/purpose-${KFMIN}:5
-	firmware? ( >=sys-apps/fwupd-1.5.0 )
-	flatpak? (
-		>=dev-libs/appstream-0.15.3:=
-		sys-apps/flatpak
-	)
-	telemetry? ( dev-libs/kuserfeedback:5 )
-	webengine? ( >=dev-qt/qtwebview-${QTMIN}:5 )
-"
-RDEPEND="${DEPEND}
-	>=dev-qt/qtquickcontrols2-${QTMIN}:5
-"
-BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
-
-PATCHES=( "${FILESDIR}/${PN}-5.25.90-tests-optional.patch" )
-
-src_prepare() {
-	ecm_src_prepare
-	# we don't need it with PackageKitBackend off
-	ecm_punt_kf_module Archive
-	# we don't do anything with this
-	sed -e "s/^pkg_check_modules.*RpmOstree/#&/" \
-		-e "s/^pkg_check_modules.*Ostree/#&/" \
-		-i CMakeLists.txt || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
-		-DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
-		-DWITH_KCM=OFF
-		-DBUILD_FlatpakBackend=$(usex flatpak)
-		$(cmake_use_find_package flatpak AppStreamQt)
-		-DBUILD_FwupdBackend=$(usex firmware)
-		$(cmake_use_find_package telemetry KUserFeedback)
-		$(cmake_use_find_package webengine Qt5WebView)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	# bug 686392: needs network connection
-	local myctestargs=(
-		-E "(knsbackendtest|flatpaktest)"
-	)
-
-	ecm_src_test
-}