kde-plasma/kinfocenter: 5.20.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/kde-plasma/kinfocenter/Manifest b/kde-plasma/kinfocenter/Manifest
index 872d2c714d8..35a8aa09ee7 100644
--- a/kde-plasma/kinfocenter/Manifest
+++ b/kde-plasma/kinfocenter/Manifest
@@ -1,2 +1,3 @@
 DIST glogo-small.png 24583 BLAKE2B 0af2ceae708e56f217120e5d8b880fb71401e3761ab26c4af5e74c0622368aa4e34b05160fae15fbfbbc832077810ab5c1e424826632748299fd22997cbe665c SHA512 648be463ec3812a2edcdab54d7a230bf2bd7e6895f4ffe72321d8fca28a5e1e0980f6e3b9a32f369c8369943ceb802a65a94b9dad820dcf2c81d4581d814cb48
 DIST kinfocenter-5.19.90.tar.xz 1295268 BLAKE2B 23afa94b768ad10feddc59c2bca3b290bf26ce00416831ed8e5634c62b9b682c2b842254afa9a8a903dd6f7ab7fc99fc82232459b514941c94fe0de129cb8c0a SHA512 ea1d1f04274aae315471a949e70e8490b1674716bc292d7eba8817f71b5589cf9ed835fb8c1be620db91f9d71d08e2a6757859a7823a916a784616d4d8cf76f8
+DIST kinfocenter-5.20.0.tar.xz 1279124 BLAKE2B 079a78690084449ee5871ce2160d35a4f7a6bda39b942989ada002a817f933255cdc8e51f5b2abfa11b0d8ce048d30ad5dbdfb9d916231513bcb35e4c597fc39 SHA512 8e544db63341cf29e578271b29272d2407c014ddf181ba61f83c6200643e66433e06c067620bd18c9a0a5e337d794800c0e5ca762a2ff733c1de76551fdd5b11
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.20.0.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.20.0.ebuild
new file mode 100644
index 00000000000..b2b2ba545e1
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.20.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.74.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.0
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://userbase.kde.org/KInfoCenter"
+SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="gles2-only ieee1394 +opengl +pci wayland"
+
+REQUIRED_USE="wayland? ( || ( opengl gles2-only ) )"
+
+BDEPEND=">=dev-util/cmake-3.14.3"
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	x11-libs/libX11
+	gles2-only? ( media-libs/mesa[gles2] )
+	ieee1394? ( sys-libs/libraw1394 )
+	opengl? (
+		media-libs/mesa[X(+)]
+		!gles2-only? ( media-libs/glu )
+	)
+	pci? ( sys-apps/pciutils )
+	wayland? (
+		>=kde-frameworks/kwayland-${KFMIN}:5
+		media-libs/mesa[egl]
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/systemsettings-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ieee1394 RAW1394)
+		$(cmake_use_find_package pci PCIUTILS)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+	)
+
+	if has_version "dev-qt/qtgui[gles2-only]"; then
+		mycmakeargs+=( $(cmake_use_find_package gles2-only OpenGLES) )
+	else
+		mycmakeargs+=( $(cmake_use_find_package opengl OpenGL) )
+	fi
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${DISTDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "NFS information module" net-fs/nfs-utils
+		optfeature "Samba status information module" net-fs/samba
+	fi
+	ecm_pkg_postinst
+}