dev-libs/kopeninghours: Add 23.04 stable branch

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-libs/kopeninghours/kopeninghours-23.04.49.9999.ebuild b/dev-libs/kopeninghours/kopeninghours-23.04.49.9999.ebuild
new file mode 100644
index 00000000000..a5666d60e8d
--- /dev/null
+++ b/dev-libs/kopeninghours/kopeninghours-23.04.49.9999.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="true"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.104.0
+QTMIN=5.15.5
+PYTHON_COMPAT=( python3_{9..11} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Library for parsing and evaluating OSM opening hours expressions"
+HOMEPAGE="https://api.kde.org/kopeninghours/html/index.html
+https://invent.kde.org/libraries/kopeninghours"
+
+LICENSE="LGPL-2+"
+SLOT="5"
+KEYWORDS=""
+IUSE="python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/kpublictransport-${PVCUT}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	sys-libs/zlib
+	python? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-22.04.0-boostpython.patch )
+
+pkg_setup() {
+	ecm_pkg_setup
+	python_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package python Boost)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	python_optimize
+}