dev-util/kdevelop*: 5.5.80 version bump (5.6 beta)

See also: https://www.kdevelop.org/news/kdevelop-5580-released

Package-Manager: Portage-3.0.3, Repoman-3.0.0
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

6 files changed, 260 insertions, 0 deletions

diff --git a/dev-util/kdevelop-php/Manifest b/dev-util/kdevelop-php/Manifest
new file mode 100644
index 00000000000..42628111870
--- /dev/null
+++ b/dev-util/kdevelop-php/Manifest
@@ -0,0 +1 @@
+DIST kdev-php-5.5.80.tar.xz 1063540 BLAKE2B c5ca691ab52df621e6ca3dc7fe261349f112cf9f8175acd56d8b5682af0d5d9bc7a5131471b653d988f935bdf5da253a6e859c7e4b610bc4333d55047c7bbd2c SHA512 5f20c871902357e7dcbb33eb98323fe4e7be2e57c958069ab689d52cfb883d8828f02c3984815b8b52028dbd804bc8bd3875710a034e677234e94333e91e7d63
diff --git a/dev-util/kdevelop-php/kdevelop-php-5.5.80.ebuild b/dev-util/kdevelop-php/kdevelop-php-5.5.80.ebuild
new file mode 100644
index 00000000000..e795d53fbb9
--- /dev/null
+++ b/dev-util/kdevelop-php/kdevelop-php-5.5.80.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_HANDBOOK_DIR="docs"
+ECM_TEST="true"
+KDE_ORG_CATEGORY="kdevelop"
+KDE_ORG_NAME="kdev-php"
+KFMIN=5.70.0
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="PHP plugin for KDevelop"
+HOMEPAGE="https://www.kdevelop.org/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+IUSE=""
+
+BDEPEND="
+	test? ( dev-util/kdevelop:5[test] )
+"
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	dev-util/kdevelop-pg-qt:5
+	dev-util/kdevelop:5=
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/threadweaver-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+# remaining tests fail for some, bug 668530
+RESTRICT+=" test"
+
+src_test() {
+	# tests hang, bug 667922
+	local myctestargs=(
+		-E "(completionbenchmark|duchain_multiplefiles)"
+	)
+	ecm_src_test
+}
diff --git a/dev-util/kdevelop-python/Manifest b/dev-util/kdevelop-python/Manifest
new file mode 100644
index 00000000000..5bad69c068f
--- /dev/null
+++ b/dev-util/kdevelop-python/Manifest
@@ -0,0 +1 @@
+DIST kdev-python-5.5.80.tar.xz 1076052 BLAKE2B 2f1a2c9d0beeabda3d5705a15fe6b9b76050fbfed4b90873afd8511dcd06f95d4af6be3e9749acc337be6fdf8d24015d518a6e34a6ac209cc0d8666723588c84 SHA512 6e11144e4caef20102bcebea4eb2b2f3de0f341af33a6b7b0b55afcbdc9c08ece75ba2e234b7718b293952e4bec9194c21c03de69c2ce56e9b6aaf5f35ec36e0
diff --git a/dev-util/kdevelop-python/kdevelop-python-5.5.80.ebuild b/dev-util/kdevelop-python/kdevelop-python-5.5.80.ebuild
new file mode 100644
index 00000000000..e89bd31e7e5
--- /dev/null
+++ b/dev-util/kdevelop-python/kdevelop-python-5.5.80.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="kdevelop"
+KDE_ORG_NAME="kdev-python"
+PYTHON_COMPAT=( python3_{7,8} )
+KFMIN=5.70.0
+QTMIN=5.12.3
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Python plugin for KDevelop"
+HOMEPAGE="https://www.kdevelop.org/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	dev-util/kdevelop:5=
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/threadweaver-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pycodestyle[${PYTHON_MULTI_USEDEP}]
+	')
+"
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
diff --git a/dev-util/kdevelop/Manifest b/dev-util/kdevelop/Manifest
new file mode 100644
index 00000000000..eb49e503585
--- /dev/null
+++ b/dev-util/kdevelop/Manifest
@@ -0,0 +1 @@
+DIST kdevelop-5.5.80.tar.xz 7139128 BLAKE2B dda023acbc977f78e43b45622a8ff925c03e12b6b2a5b81b219659d3f1d41e27b24edc25f1a7ea3da6ae27edcacae6c867bcff1e6f77dbda93bbe9b36631defb SHA512 2da614df5a890b748de7f18c37027739d8537b6aef3a9ece33b7f5d0bc2627832e4e9465a390219dd2336e79a81dd93febe645d028e10755917d1fd0ce93992a
diff --git a/dev-util/kdevelop/kdevelop-5.5.80.ebuild b/dev-util/kdevelop/kdevelop-5.5.80.ebuild
new file mode 100644
index 00000000000..4c739152206
--- /dev/null
+++ b/dev-util/kdevelop/kdevelop-5.5.80.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KDE_ORG_CATEGORY="kdevelop"
+KFMIN=5.70.0
+QTMIN=5.12.3
+VIRTUALDBUS_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Integrated Development Environment, supporting KF5/Qt, C/C++ and much more"
+HOMEPAGE="https://www.kdevelop.org/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5/55" # look at KDEVELOP_SOVERSION inside CMakeLists.txt
+IUSE="+gdbui hex +plasma +qmake reviewboard subversion"
+
+COMMON_DEPEND="
+	dev-libs/grantlee:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qthelp-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qttest-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-util/astyle-3.1:=
+	kde-apps/libkomparediff2:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	>=kde-frameworks/threadweaver-${KFMIN}:5
+	>=sys-devel/clang-6.0:=
+	gdbui? ( kde-plasma/libksysguard:5= )
+	hex? ( app-editors/okteta:5 )
+	plasma? (
+		>=kde-frameworks/krunner-${KFMIN}:5
+		>=kde-frameworks/plasma-${KFMIN}:5
+	)
+	qmake? ( dev-util/kdevelop-pg-qt:5 )
+	reviewboard? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	subversion? (
+		dev-libs/apr:1
+		dev-libs/apr-util:1
+		dev-vcs/subversion
+	)
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	dev-util/ninja
+	kde-apps/kapptemplate:5
+	kde-apps/kio-extras:5
+	>=sys-devel/gdb-7.0[python]
+	reviewboard? ( kde-apps/ktp-accounts-kcm:5 )
+	!dev-util/kdevelop-clang-tidy
+"
+
+RESTRICT+=" test"
+# see bug 366471
+
+src_configure() {
+	local clang_version=$(best_version sys-devel/clang)
+	local llvm_root="/usr/lib/llvm/$(ver_cut 1 ${clang_version##sys-devel/clang-})"
+
+	local mycmakeargs=(
+		-DLLVM_ROOT=${llvm_root}
+		$(cmake_use_find_package gdbui KSysGuard)
+		-DBUILD_executeplasmoid=$(usex plasma)
+		$(cmake_use_find_package plasma KF5Plasma)
+		$(cmake_use_find_package hex OktetaKastenControllers)
+		$(cmake_use_find_package qmake KDevelop-PG-Qt)
+		$(cmake_use_find_package reviewboard KF5Purpose)
+		$(cmake_use_find_package subversion SubversionLibrary)
+	)
+
+	use gdbui || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_KF5SysGuard=ON )
+	use reviewboard || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_KDEExperimentalPurpose=ON )
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-apps/konsole" ; then
+		elog "For konsole view, please install kde-apps/konsole"
+	fi
+
+	if ! has_version "dev-util/cppcheck" ; then
+		elog "For static C/C++ code analysis support, please install dev-util/cppcheck"
+	fi
+
+	if ! has_version "dev-util/heaptrack[qt5]" ; then
+		elog "For heap memory profiling support, please install dev-util/heaptrack"
+	fi
+
+	if ! has_version "dev-util/clazy" ; then
+		elog "For static C++ Qt code analysis support, please install dev-util/clazy"
+	fi
+
+	if ! has_version ">=dev-util/meson-0.51" ; then
+		elog "For the Meson Project manager plugin, please install dev-util/meson"
+	fi
+}