Merge updates from master

10 files changed, 297 insertions, 0 deletions

diff --git a/dev-util/kdevelop-php/Manifest b/dev-util/kdevelop-php/Manifest
new file mode 100644
index 00000000000..77ab399424c
--- /dev/null
+++ b/dev-util/kdevelop-php/Manifest
@@ -0,0 +1 @@
+DIST kdev-php-25.12.0.tar.xz 1101020 BLAKE2B 92fb0e6179369d7bc1e53003542bf6629bccf23a914373707f461e840ca372795cd1b6c72071e56768f6533127b9fe5e62c1d73b38af7d9f346a2d25574f7633 SHA512 3cfdd3a388ee2b85638ea6a03c5c4b3bd93d9d706e269a16bc47dde0d33a7ed4a43ed492972eb1b4a88a83a3fdc302c6cde0c960f9de4c69e06b9336aa057f8f
diff --git a/dev-util/kdevelop-php/kdevelop-php-25.12.0.ebuild b/dev-util/kdevelop-php/kdevelop-php-25.12.0.ebuild
new file mode 100644
index 00000000000..060ca2a3220
--- /dev/null
+++ b/dev-util/kdevelop-php/kdevelop-php-25.12.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_HANDBOOK_DIR="docs"
+ECM_TEST="true"
+KDE_ORG_CATEGORY="kdevelop"
+KDE_ORG_NAME="kdev-php"
+KFMIN=6.19.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="PHP plugin for KDevelop"
+HOMEPAGE="https://kdevelop.org/"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE=""
+
+# remaining tests fail for some, bug 668530
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	dev-util/kdevelop:6=
+	>=dev-util/kdevelop-pg-qt-2.3.0:0
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/threadweaver-${KFMIN}:6
+"
+RDEPEND="${DEPEND}"
+BDEPEND="test? ( dev-util/kdevelop:6[test] )"
+
+src_test() {
+	# tests hang, bug 667922
+	local myctestargs=(
+		-E "(completionbenchmark|duchain_multiplefiles)"
+	)
+	ecm_src_test
+}
diff --git a/dev-util/kdevelop-python/Manifest b/dev-util/kdevelop-python/Manifest
new file mode 100644
index 00000000000..43978cc9884
--- /dev/null
+++ b/dev-util/kdevelop-python/Manifest
@@ -0,0 +1 @@
+DIST kdev-python-25.12.0.tar.xz 1139552 BLAKE2B 16e4ee767ae359e7c8ce1fc58c2087d23cc33aa9f0d91a01ca31376eb629ff8fe96e36e057b641998411724c5cbd2c977e23e0b43ffb415fad8c7e5cd6b9d97b SHA512 184d6fe5befcf7cfe992872142da2f5e736de7466c2cda75e6c061405ffd45b367e3aa15c29bcb240e587cf369d2b1ce64da01835db063207fbf7bbdf0a78be4
diff --git a/dev-util/kdevelop-python/kdevelop-python-25.12.0.ebuild b/dev-util/kdevelop-python/kdevelop-python-25.12.0.ebuild
new file mode 100644
index 00000000000..cec9f11dfa7
--- /dev/null
+++ b/dev-util/kdevelop-python/kdevelop-python-25.12.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="kdevelop"
+KDE_ORG_NAME="kdev-python"
+PYTHON_COMPAT=( python3_{11..14} )
+KFMIN=6.19.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Python plugin for KDevelop"
+HOMEPAGE="https://kdevelop.org/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	dev-util/kdevelop:6=
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/threadweaver-${KFMIN}:6
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/kdevelop:6=[test?]
+"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pycodestyle[${PYTHON_USEDEP}]
+	')
+"
diff --git a/dev-util/kdevelop/Manifest b/dev-util/kdevelop/Manifest
new file mode 100644
index 00000000000..9ae051f5a98
--- /dev/null
+++ b/dev-util/kdevelop/Manifest
@@ -0,0 +1 @@
+DIST kdevelop-25.12.0.tar.xz 9012356 BLAKE2B 01ea64b66481ea11596b77c6b4c5446daa13e0dfed362f8ada0e861fd32b6930fc4aa1c4805dd96c138cfaa95abacd9d8ed62c945aa1ab81ffe995ef63a9cf35 SHA512 57a0b19ad6317fbb2af5737c4df66fc3d05f0c25d8e47c3563cc13f08197ae8de4cda2da0de138641e1259880d2c4173fbcbbbfb1cffae357b9e24fcc26b73f1
diff --git a/dev-util/kdevelop/kdevelop-25.12.0.ebuild b/dev-util/kdevelop/kdevelop-25.12.0.ebuild
new file mode 100644
index 00000000000..281c5a2060a
--- /dev/null
+++ b/dev-util/kdevelop/kdevelop-25.12.0.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_QA_COMPAT_SKIP=1 # bug 964762
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KDE_ORG_CATEGORY="kdevelop"
+KFMIN=6.19.0
+LLVM_COMPAT=( 15 16 17 18 19 20 21 )
+QTMIN=6.9.1
+inherit ecm gear.kde.org llvm-r2 optfeature xdg
+
+DESCRIPTION="Integrated Development Environment, supporting KF6/Qt, C/C++ and much more"
+HOMEPAGE="https://kdevelop.org/"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="6/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gdbui plasma +qmake +share subversion"
+
+# UPSTREAM: not ported yet, check plugins/CMakeLists.txt
+# IUSE="hex"
+# 	hex? ( app-editors/okteta:6 )
+COMMON_DEPEND="
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qttools-${QTMIN}:6[assistant]
+	>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
+	>=dev-util/astyle-3.1:=
+	kde-apps/libkomparediff2:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kbookmarks-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/ktexttemplate-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/sonnet-${KFMIN}:6
+	>=kde-frameworks/threadweaver-${KFMIN}:6
+	$(llvm_gen_dep 'llvm-core/clang:${LLVM_SLOT}')
+	gdbui? ( kde-plasma/libksysguard:6= )
+	plasma? (
+		>=kde-frameworks/krunner-${KFMIN}:6
+		kde-plasma/libplasma:6
+	)
+	qmake? ( >=dev-util/kdevelop-pg-qt-2.4.0:0 )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
+	subversion? (
+		dev-libs/apr:1
+		dev-libs/apr-util:1
+		dev-vcs/subversion
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+RDEPEND="${COMMON_DEPEND}
+	app-alternatives/ninja
+	>=dev-debug/gdb-7.0[python]
+	>=dev-qt/qttools-${QTMIN}:6[qdbus]
+	kde-apps/kapptemplate:*
+	kde-apps/kio-extras:6
+"
+
+CMAKE_SKIP_TESTS=(
+	# D-Bus required
+	test_{{project,session}controller,midbus,definesandincludes,kdevgit}
+	test_{compilerprovider,cmakemanager,ctestfindsuites,cmakefileapi}
+	test_{custombuildsystemplugin,qmakeproject,projectload,craftruntime}
+	bench_codecompletion # segfaults
+	test_gdb # FIXME: fails to launch xterm (if found)
+	test_{path,generationtest} # FIXME: whatever that does, does not work
+)
+
+src_prepare() {
+	rm -r plugins/qmljs || die # bug 960669, unused upstream
+	ecm_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLVM_ROOT="$(get_llvm_prefix)"
+		$(cmake_use_find_package gdbui KSysGuard)
+		-DBUILD_executeplasmoid=$(usex plasma)
+		$(cmake_use_find_package plasma Plasma)
+		$(cmake_use_find_package qmake KDevelopPGQt)
+		$(cmake_use_find_package share KF6Purpose)
+		$(cmake_use_find_package subversion SubversionLibrary)
+	)
+#		$(cmake_use_find_package hex OktetaKastenControllers)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "konsole view" "kde-apps/konsole:6"
+		optfeature "static C++ Qt code analysis" dev-util/clazy
+		optfeature "static C/C++ code analysis" dev-util/cppcheck
+		optfeature "heap memory profiling" "dev-util/heaptrack[gui]"
+		optfeature "meson project manager plugin" dev-build/meson
+		optfeature "formatting configurations via customscript plugin" dev-util/indent
+		optfeature "formatting configurations via customscript plugin" dev-util/uncrustify
+	fi
+	xdg_pkg_postinst
+}
diff --git a/dev-util/kio-perldoc/Manifest b/dev-util/kio-perldoc/Manifest
new file mode 100644
index 00000000000..bdca871deac
--- /dev/null
+++ b/dev-util/kio-perldoc/Manifest
@@ -0,0 +1 @@
+DIST kdesdk-kio-25.12.0.tar.xz 42956 BLAKE2B 4b695179f4c27d192a5cdbbe1884acf74bdeb340caff95256a2ab701a970174b727f2a615917ad70df9a6112d6ae40e0b56943d89ff973128ba786d9dd07021b SHA512 7a8a063b64a3e022f5c0f3cc52642fce9e28becb49ff164731534ef77bfda61b8b01c031ca86219d38587d61305a5d2e7da1c2a200d166e900962c9bb8319ae6
diff --git a/dev-util/kio-perldoc/kio-perldoc-25.12.0.ebuild b/dev-util/kio-perldoc/kio-perldoc-25.12.0.ebuild
new file mode 100644
index 00000000000..db032baed14
--- /dev/null
+++ b/dev-util/kio-perldoc/kio-perldoc-25.12.0.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="kdesdk-kio"
+KFMIN=6.19.0
+inherit ecm gear.kde.org
+
+DESCRIPTION="KIO worker interface to browse Perl documentation"
+
+LICENSE="GPL-2+ || ( Artistic GPL-1+ )"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	dev-lang/perl
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-util/massif-visualizer/Manifest b/dev-util/massif-visualizer/Manifest
new file mode 100644
index 00000000000..c9da56462c2
--- /dev/null
+++ b/dev-util/massif-visualizer/Manifest
@@ -0,0 +1 @@
+DIST massif-visualizer-25.12.0.tar.xz 286048 BLAKE2B 8502feed53d2ed6e55466c35d492bc1203f0e1c99a82103fe95a02aa539fd4befb921c719e6ab983c683c3d5deae82038b4e8c2c2e66a8267045ecf7df38b799 SHA512 90bd95d067f46a00a37d914612e736ab39114e6e987fae3c9d0adac45aa2d3e0d30e25d21f2a8df6c85a33c52e044f5107588b798c6e100ee608564efd06c65f
diff --git a/dev-util/massif-visualizer/massif-visualizer-25.12.0.ebuild b/dev-util/massif-visualizer/massif-visualizer-25.12.0.ebuild
new file mode 100644
index 00000000000..f246701d041
--- /dev/null
+++ b/dev-util/massif-visualizer/massif-visualizer-25.12.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KFMIN=6.19.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Tool visualising massif data"
+HOMEPAGE="https://apps.kde.org/massif_visualizer/"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+callgraph"
+
+DEPEND="
+	dev-libs/kdiagram:6
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	callgraph? ( >=media-gfx/kgraphviewer-2.5.0:0 )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package callgraph KGraphViewerPart)
+	)
+	ecm_src_configure
+}