Introduce KDE Applications.

All packages which have a KDE Applications release have moved from kde-base to
kde-apps.

9999 is back, and is upstream master (whether it be KDE 4 or KF5). For packages
with an unreleased KF5 branch, 5.9999 is used.

1 files changed, 63 insertions, 0 deletions

diff --git a/kde-apps/cantor/cantor-9999.ebuild b/kde-apps/cantor/cantor-9999.ebuild
new file mode 100644
index 00000000000..33897eb7c44
--- /dev/null
+++ b/kde-apps/cantor/cantor-9999.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+PYTHON_COMPAT=( python2_7 )
+inherit kde4-base python-single-r1
+
+DESCRIPTION="KDE4 interface for doing mathematics and scientific computing"
+HOMEPAGE="http://www.kde.org/applications/education/cantor http://edu.kde.org/cantor"
+KEYWORDS=""
+IUSE="analitza debug postscript python qalculate +R"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+RDEPEND="
+	analitza? ( $(add_kdebase_dep analitza) )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate
+	)
+	postscript? ( app-text/libspectre )
+	python? ( ${PYTHON_DEPS} )
+	R? ( dev-lang/R )
+	dev-qt/qtxmlpatterns:4
+"
+DEPEND="${RDEPEND}
+	>=dev-cpp/eigen-2.0.3:2
+"
+
+RESTRICT="test"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with analitza)
+		$(cmake-utils_use_with postscript LibSpectre)
+		$(cmake-utils_use_with python PythonLibs)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with R)
+	)
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if ! use analitza && ! use python && ! use qalculate && ! use R; then
+		echo
+		ewarn "You have decided to build ${PN} with no backend."
+		ewarn "To have this application functional, please do one of below:"
+		ewarn "    # emerge -va1 '='${CATEGORY}/${P} with 'analitza', 'python', 'qalculate' or 'R' USE flag enabled"
+		ewarn "    # emerge -vaDu sci-mathematics/maxima"
+		echo
+	fi
+}