kde-apps/k3b: 25.03.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index c86d9b86ba1..c29431940b7 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1 +1,2 @@
 DIST k3b-25.03.80.tar.xz 10755132 BLAKE2B 4c956128721f5aa568261e5099acf69c1ac868381beaaa82ccf2db82f6182eb100d1796ade7c6ff2f87c412f7d83c3020a16ed23b836ff41e9d4ea7fd518af86 SHA512 274ad96698b70718ec0201204f6a6e23f899ecfeb54e29de04b2bc94e0ffd509c30a34ece78162179a5ce06d3936a76282cefac6b67245f4c37b6a2b02052909
+DIST k3b-25.03.90.tar.xz 10755832 BLAKE2B bceda08ea046aec8980aec6d817dbff888beb2c81e846b7adf971ecd1ac7ea298d01a1053b52e6b549186f8d813d91e5b4c014eb0bafa5d03acb4efe9edf9fa7 SHA512 2748f443a11fdc6353c13ce21f12bd0d4d890125e57b58208ccedca35b0677387feb77d6dad1c33f3819ef064f7ba34d87479df064bfec2af99e03c6b6938ad3
diff --git a/kde-apps/k3b/k3b-25.03.90.ebuild b/kde-apps/k3b/k3b-25.03.90.ebuild
new file mode 100644
index 00000000000..ce407e7dbbe
--- /dev/null
+++ b/kde-apps/k3b/k3b-25.03.90.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.9.0
+QTMIN=6.7.2
+inherit ecm flag-o-matic gear.kde.org xdg
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/k3b/ https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dvd ffmpeg flac lame mad musepack sndfile sox taglib vcd vorbis webengine"
+
+REQUIRED_USE="flac? ( taglib ) lame? ( taglib ) sox? ( taglib )"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=kde-apps/libkcddb-${PVCUT}:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kbookmarks-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kfilemetadata-${KFMIN}:6[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? ( >=media-video/ffmpeg-4.4.0:0= )
+	flac? ( >=media-libs/flac-1.2:=[cxx] )
+	lame? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5:= )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6 )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	app-cdr/cdrtools
+	dev-libs/libburn
+	media-sound/cdparanoia
+	dvd? ( >=app-cdr/dvd+rw-tools-7 )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	# -Werror=odr, -Werror=lto-type-mismatch
+	# https://bugs.gentoo.org/924376
+	# https://bugs.kde.org/show_bug.cgi?id=492571
+	filter-lto
+
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=ON
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex lame)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake_use_find_package webengine Qt6WebEngineWidgets)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	elog
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+}