kde-apps/libkleo: 23.08.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/kde-apps/libkleo/libkleo-23.08.5.ebuild b/kde-apps/libkleo/libkleo-23.08.5.ebuild
new file mode 100644
index 00000000000..5bc0d8a7fcd
--- /dev/null
+++ b/kde-apps/libkleo/libkleo-23.08.5.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="true"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Library for encryption handling"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+fancyviewer"
+
+RDEPEND="
+	>=app-crypt/gpgme-1.16.0:=[cxx,qt5]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	fancyviewer? ( >=kde-apps/kpimtextedit-${PVCUT}:5 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package fancyviewer KPim5TextEdit)
+	)
+
+	ecm_src_configure
+}