kde-apps/cantor: drop 25.07.90

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 117 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
index ddbe9df8480..9faf2aa8504 100644
--- a/kde-apps/cantor/Manifest
+++ b/kde-apps/cantor/Manifest
@@ -1,2 +1 @@
-DIST cantor-25.07.90.tar.xz 10906928 BLAKE2B 1a7303acd03df7af1ecba869ef37f1e098c9f250254835906faf247f49db643b3f23fcf551f615d86200524355eceffc55ed603f3563211401091e6f821db21a SHA512 f4bff4e95d970b32c02eb72472e920f71cd61fecf5445e1cc2c76c65dd540621f93a5744a6af07d02a3326cf0167ded1c022bbc3d77549d68ce329b53ed9d4ea
 DIST cantor-25.08.0.tar.xz 10908548 BLAKE2B 87bf6868b1ba1aaefd4ce9f0693dfda4713a2e9f8429148b44727f856312a4dfbf7e4b36f8379ca2adea471039b11da1fb6ff623e0fdc985e665d7901dbf9921 SHA512 af6f9c81ab07c7e096b030bb5c52c7778699298328aa71fcfcb1303b3141d1c8dbfb43264f14b72743977cff355d624f086fcfb895f146715746a93158b4b13e
diff --git a/kde-apps/cantor/cantor-25.07.90.ebuild b/kde-apps/cantor/cantor-25.07.90.ebuild
deleted file mode 100644
index a8b7f318976..00000000000
--- a/kde-apps/cantor/cantor-25.07.90.ebuild
+++ /dev/null
@@ -1,116 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-ECM_HANDBOOK="optional"
-ECM_TEST="forceoptional"
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{11..13} )
-PVCUT=$(ver_cut 1-3)
-KFMIN=6.16.0
-QTMIN=6.9.1
-inherit ecm gear.kde.org lua-single optfeature python-single-r1 xdg
-
-DESCRIPTION="Interface for doing mathematics and scientific computing"
-HOMEPAGE="https://apps.kde.org/cantor/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64 ~arm64"
-IUSE="+analitza julia lua postscript python qalculate R webengine"
-
-REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test"
-
-# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
-DEPEND="
-	>=app-text/poppler-23.12.0[qt6]
-	dev-libs/libxml2:2=
-	dev-libs/libxslt
-	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets,xml]
-	>=dev-qt/qtsvg-${QTMIN}:6
-	>=kde-frameworks/karchive-${KFMIN}:6
-	>=kde-frameworks/kcompletion-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/knewstuff-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/ktexteditor-${KFMIN}:6
-	>=kde-frameworks/ktextwidgets-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
-	analitza? ( >=kde-apps/analitza-${PVCUT}:6 )
-	julia? ( dev-lang/julia )
-	lua? ( ${LUA_DEPS} )
-	qalculate? (
-		sci-libs/cln
-		sci-libs/libqalculate:=
-	)
-	postscript? ( app-text/libspectre )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-qt/qtbase-${QTMIN}:6[dbus]
-	)
-	R? ( dev-lang/R )
-	webengine? (
-		>=dev-qt/qttools-${QTMIN}:6[assistant]
-		>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
-	)
-"
-# !analitza?
-RDEPEND="${DEPEND}
-	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
-		|| (
-			sci-mathematics/maxima
-			sci-mathematics/octave
-		)
-	) ) ) ) ) )
-"
-BDEPEND="x11-misc/shared-mime-info"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-}
-
-src_configure() {
-	use julia && addpredict /proc/self/mem # bug 602894
-
-	local mycmakeargs=(
-		$(cmake_use_find_package analitza Analitza6)
-		$(cmake_use_find_package julia Julia)
-		$(cmake_use_find_package lua LuaJIT)
-		-DUSE_LIBSPECTRE=$(usex postscript)
-		$(cmake_use_find_package python Python3)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package R R)
-		-DENABLE_EMBEDDED_DOCUMENTATION=$(usex webengine)
-	)
-	use lua && mycmakeargs+=(
-		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
-		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
-	)
-	ecm_src_configure
-}
-
-src_compile() {
-	# -j1 for bug #919576
-	MAKEOPTS="-j1" ecm_src_compile
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Maxima backend" sci-mathematics/maxima
-		optfeature "Octave backend" sci-mathematics/octave
-		optfeature "LaTeX support" virtual/latex-base
-	fi
-	xdg_pkg_postinst
-}