kde-apps/kaccounts-integration: 24.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 90 insertions, 0 deletions

diff --git a/kde-apps/kaccounts-integration/Manifest b/kde-apps/kaccounts-integration/Manifest
index 69acae941cf..8c0924702cf 100644
--- a/kde-apps/kaccounts-integration/Manifest
+++ b/kde-apps/kaccounts-integration/Manifest
@@ -1 +1,2 @@
 DIST kaccounts-integration-24.11.90.tar.xz 93420 BLAKE2B 6bc574a0dd2c3d952f1da82204adef9b305a49c18a280f8f7a6d069e66e551548836b83a64cd07d6d125c81a4204cfe6ddcec958dfef42c9e4d32ca810dd698b SHA512 734d4eda37b9ace6856d8ab55ba34c20e8c78ba662f2effcbd682ecf01f6b68c891a4097ac861ac22154d1519afba455bf68553d7e7fcdc6f63fdab016882457
+DIST kaccounts-integration-24.12.0.tar.xz 93484 BLAKE2B 85adcb69b5fa12ebaa7cc4191f97095e78bb984c54ab98b50821909ba71671a058996f4a112c5ffd28c07967311997b6d433b420e9651325f995ba9f0240bd84 SHA512 d6ec7c7b6d1eb8d6b63e7f0eb2d3d3b4c31106e19a928392f8e3b3078d230f0f7a3cb9e969a7875bce1602df30f4a47883fb6004e27cd3f9bfc675983d31c66b
diff --git a/kde-apps/kaccounts-integration/kaccounts-integration-24.12.0.ebuild b/kde-apps/kaccounts-integration/kaccounts-integration-24.12.0.ebuild
new file mode 100644
index 00000000000..f800e06d130
--- /dev/null
+++ b/kde-apps/kaccounts-integration/kaccounts-integration-24.12.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KF5MIN=5.115.0
+KFMIN=6.5.0
+PVCUT=$(ver_cut 1-3)
+QT5MIN=5.15.12
+QTMIN=6.7.2
+VIRTUALDBUS_TEST="true"
+inherit ecm gear.kde.org multibuild
+
+DESCRIPTION="Administer web accounts for the sites and services across the Plasma desktop"
+HOMEPAGE="https://community.kde.org/KTp"
+
+LICENSE="LGPL-2.1"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE="qt5"
+
+# bug #549444
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=net-libs/accounts-qt-1.17[qt5(-)?,qt6(+)]
+	>=net-libs/signond-8.61-r100[qt5(-)?,qt6(+)]
+	qt5? (
+		>=dev-qt/qtdeclarative-${QT5MIN}:5
+		>=dev-qt/qtgui-${QT5MIN}:5
+		>=dev-qt/qtwidgets-${QT5MIN}:5
+		>=kde-frameworks/kconfig-${KF5MIN}:5
+		>=kde-frameworks/kcoreaddons-${KF5MIN}:5
+		>=kde-frameworks/kdbusaddons-${KF5MIN}:5
+		>=kde-frameworks/ki18n-${KF5MIN}:5
+		>=kde-frameworks/kio-${KF5MIN}:5
+		>=kde-frameworks/kwallet-${KF5MIN}:5
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/qcoro
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	qt5? (
+		dev-libs/qcoro5
+		>=kde-frameworks/kcmutils-${KF5MIN}:5
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-apps/signon-kwallet-extension:6
+"
+BDEPEND="sys-devel/gettext"
+PDEPEND=">=kde-apps/kaccounts-providers-${PVCUT}:6"
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) default )
+}
+
+src_configure() {
+	my_src_configure() {
+		if [[ ${MULTIBUILD_VARIANT} == qt5 ]]; then
+			local mycmakeargs=( -DKF6_COMPAT_BUILD=ON )
+		fi
+
+		ecm_src_configure
+	}
+
+	multibuild_foreach_variant my_src_configure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant ecm_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant ecm_src_install
+}