kde-apps/akonadi: drop 24.01.95

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 0 insertions, 108 deletions

diff --git a/kde-apps/akonadi/Manifest b/kde-apps/akonadi/Manifest
index 23dd05839fa..63ed62cf9ac 100644
--- a/kde-apps/akonadi/Manifest
+++ b/kde-apps/akonadi/Manifest
@@ -1,2 +1 @@
-DIST akonadi-24.01.95.tar.xz 1684956 BLAKE2B 3508942b6d8a5fa0ec7a6dac88df4a7f54703e7cc986250d4d54dc8903f952725c3a253dce1c2941c0f19d5f92a4098f56c4d4b2487026fb30da74d96967ddc2 SHA512 697ec8f1545751415c5223e18538f042ec7128d20cb9e7cc952a6bbdb82d0b07f50aac331c2f87a5b183c32aa2756c18adff97614e51f6921d962f819475c45e
 DIST akonadi-24.02.0.tar.xz 1689776 BLAKE2B 17511e725f38543c8c262bcdefc4b01f4d2653875069e53349cd6ad1ab7052e40a10ece33ea9661ceeba00fba75c5978d2584799b47015eb3d801ad9cbeb2369 SHA512 89f4b9030fd1d87a3928eec43967b47508a0dbf8d14877d370f1b1d77a86297339b2b23530b8c29b0bbcc672a5dcfffbfe32671876ea9e843466ec3d79b2e408
diff --git a/kde-apps/akonadi/akonadi-24.01.95.ebuild b/kde-apps/akonadi/akonadi-24.01.95.ebuild
deleted file mode 100644
index d733827a2b8..00000000000
--- a/kde-apps/akonadi/akonadi-24.01.95.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_DESIGNERPLUGIN="true"
-ECM_QTHELP="true"
-ECM_TEST="forceoptional"
-KFMIN=5.249.0
-QTMIN=6.6.2
-VIRTUALDBUS_TEST="true"
-inherit ecm gear.kde.org readme.gentoo-r1
-
-DESCRIPTION="Storage service for PIM data and libraries for PIM apps"
-HOMEPAGE="https://community.kde.org/KDE_PIM/akonadi"
-
-LICENSE="LGPL-2.1+"
-SLOT="6"
-KEYWORDS="~amd64"
-IUSE="+kaccounts +mysql postgres sqlite tools xml"
-
-REQUIRED_USE="|| ( mysql postgres sqlite ) test? ( tools )"
-
-# some akonadi tests time out, that probably needs more work as it's ~700 tests
-RESTRICT="test"
-
-COMMON_DEPEND="
-	app-arch/xz-utils
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,mysql?,network,postgres?,sql,sqlite?,widgets,xml]
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/kitemmodels-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	kaccounts? (
-		kde-apps/kaccounts-integration:6
-		>=net-libs/accounts-qt-1.16_p20220803[qt6]
-	)
-	xml? ( dev-libs/libxml2 )
-"
-DEPEND="${COMMON_DEPEND}
-	dev-libs/libxslt
-	test? ( sys-apps/dbus )
-"
-RDEPEND="${COMMON_DEPEND}
-	mysql? ( virtual/mysql )
-	postgres? ( dev-db/postgresql )
-"
-
-PATCHES=( "${FILESDIR}/${PN}-21.03.80-mysql56-crash.patch" )
-
-pkg_setup() {
-	# Set default storage backend in order: MySQL, PostgreSQL, SQLite
-	# reverse driver check to keep the order
-	use sqlite && DRIVER="QSQLITE"
-	use postgres && DRIVER="QPSQL"
-	use mysql && DRIVER="QMYSQL"
-
-	if use mysql && has_version "${CATEGORY}/${PN}[mysql]" && has_version "dev-db/mariadb"; then
-		ewarn
-		ewarn "Attention: Make sure to read README.gentoo after install."
-		ewarn
-	fi
-
-	ecm_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package kaccounts AccountsQt6)
-		$(cmake_use_find_package kaccounts KAccounts6)
-		-DBUILD_TOOLS=$(usex tools)
-		$(cmake_use_find_package xml LibXml2)
-	)
-
-	ecm_src_configure
-}
-
-src_install() {
-	# Who knows, maybe it accidentally fixes our permission issues
-	cat <<-EOF > "${T}"/akonadiserverrc
-[%General]
-Driver=${DRIVER}
-EOF
-	insinto /usr/share/config/akonadi
-	doins "${T}"/akonadiserverrc
-
-	ecm_src_install
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	ecm_pkg_postinst
-	elog "You can select the storage backend in ~/.config/akonadi/akonadiserverrc."
-	elog "Available drivers are:"
-	use mysql && elog "  QMYSQL"
-	use postgres && elog "  QPSQL"
-	use sqlite && elog "  QSQLITE"
-	elog "${DRIVER} has been set as your default akonadi storage backend."
-	use mysql && elog
-	use mysql && FORCE_PRINT_ELOG=1 readme.gentoo_print_elog
-}