[kde] add 4.12.1

2 files changed, 62 insertions, 0 deletions

diff --git a/kde-base/krossruby/Manifest b/kde-base/krossruby/Manifest
new file mode 100644
index 00000000000..6a9f00f0621
--- /dev/null
+++ b/kde-base/krossruby/Manifest
@@ -0,0 +1 @@
+DIST kross-interpreters-4.12.1.tar.xz 130836 SHA256 994bcccc6a431feb97a7b3520d629b22c6c3236efb9d55aaec161509e0dd5555 SHA512 e3d28ac35b8c05158f989c9b25d121ecfcedcb400c463eca79011d5134e571f47e0b98705b4c881e0e1a5349def0472db659f091a4a8043a8f4f1e27a945eb59 WHIRLPOOL 37679002b86e0725a56abe678e162508bc44338d2f779c6e10252d59f641f81d5ed2fdb15ffaaef7edebdd271b4594b4d3b199cfdedbf7d32583420287c044c2
diff --git a/kde-base/krossruby/krossruby-4.12.1.ebuild b/kde-base/krossruby/krossruby-4.12.1.ebuild
new file mode 100644
index 00000000000..d7d678e7c8d
--- /dev/null
+++ b/kde-base/krossruby/krossruby-4.12.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kross-interpreters"
+KMMODULE="ruby"
+
+USE_RUBY="ruby19"
+# Only one ruby version is supported:
+# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-meta ruby-ng
+
+DESCRIPTION="Kross scripting framework: Ruby interpreter"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND=""
+RDEPEND=""
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-meta_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-meta_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-meta_src_prepare
+}
+
+each_ruby_configure() {
+	local CMAKE_USE_DIR=${S}
+	local mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_DIR=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+	)
+	kde4-meta_src_configure
+}
+
+each_ruby_compile() {
+	local CMAKE_USE_DIR=${S}
+	kde4-meta_src_compile
+}
+
+each_ruby_install() {
+	local CMAKE_USE_DIR=${S}
+	kde4-meta_src_install
+}