[kde-base] Add KDE SC 4.8 RC1

Signed-off-by: Alexey Shvetsov <alexxy@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/kde-base/krossruby/Manifest b/kde-base/krossruby/Manifest
index 93da865a6a9..283e4054952 100644
--- a/kde-base/krossruby/Manifest
+++ b/kde-base/krossruby/Manifest
@@ -1 +1,2 @@
 DIST kross-interpreters-4.7.90.tar.bz2 134976 SHA256 2593c4bc5d2d1610ab4fdda6b03bb8d0a0ed3c9c1008d9669e9b92e073e5d3b6 SHA512 449032b066426a8869b8f38dd9049ec42ba9e42f1a528160efdf1d994c282be8e13653b1e3d0fb371b83c8896aee71cb6b8cf89b9ee831b57edb1462301a2482 WHIRLPOOL 1191e0145f91b8357a1df36c7f9e0c3ffbb90919c05f2d2269ebc20e80a99ef1492b16d7a8c26e1d13052c1b3ec752be207ee5d19e3304826d567b698d389c4c
+DIST kross-interpreters-4.7.95.tar.bz2 134847 SHA256 eb4c292562705859f98623133739de908d5fa615ad0ef8f8e90767599b396ce8 SHA512 39c564e071f5261c0ce5860d050b4432b5d28e0485f1ef911dc961a8e06a4d0d6190509d49df640fcb478193b60b53b5a73e83fa0f1fa8183b019c4033e32b8f WHIRLPOOL f2ae894108c0f22025d007fe66644a1ff74b65c3b7ad109a769d51025cd2ad67151cce2e768ac0d60d75408135542584edde10ebaa81d9ecc7df164d7fd23462
diff --git a/kde-base/krossruby/krossruby-4.7.95.ebuild b/kde-base/krossruby/krossruby-4.7.95.ebuild
new file mode 100644
index 00000000000..153893d2fc5
--- /dev/null
+++ b/kde-base/krossruby/krossruby-4.7.95.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+KMNAME="kross-interpreters"
+KMMODULE="ruby"
+KDE_SCM="git"
+
+USE_RUBY="ruby18"
+# No ruby19 for three reasons:
+# 1) it does not build (yet) - will likely be solved soon
+# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-meta ruby-ng
+
+DESCRIPTION="Kross scripting framework: Ruby interpreter"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND=""
+RDEPEND=""
+
+# Split from kdebindings-ruby in 4.7
+add_blocker kdebindings-ruby
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-meta_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-meta_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-meta_src_prepare
+}
+
+each_ruby_configure() {
+	local CMAKE_USE_DIR=${S}
+	local mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_DIR=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+	)
+	kde4-meta_src_configure
+}
+
+each_ruby_compile() {
+	local CMAKE_USE_DIR=${S}
+	kde4-meta_src_compile
+}
+
+each_ruby_install() {
+	local CMAKE_USE_DIR=${S}
+	kde4-meta_src_install
+}