kde-frameworks: Add KDE Frameworks 5.64.0

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/kde-frameworks/frameworkintegration/frameworkintegration-5.64.0.ebuild b/kde-frameworks/frameworkintegration/frameworkintegration-5.64.0.ebuild
new file mode 100644
index 00000000000..f6721b5381a
--- /dev/null
+++ b/kde-frameworks/frameworkintegration/frameworkintegration-5.64.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_QTHELP="false"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Framework for integrating Qt applications with KDE Plasma workspaces"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="appstream X"
+
+# drop qtwidgets subslot operator when QT_MINIMAL >= 5.14.0
+DEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets '' '' '5=')
+	appstream? (
+		app-admin/packagekit-qt
+		dev-libs/appstream[qt5]
+	)
+	X? (
+		$(add_qt_dep qtx11extras)
+		x11-libs/libxcb
+	)
+"
+RDEPEND="${DEPEND}"
+
+# requires running kde environment
+RESTRICT+=" test"
+
+src_prepare() {
+	punt_bogus_dep Qt5 DBus
+	kde5_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package appstream AppStreamQt)
+		$(cmake-utils_use_find_package appstream packagekitqt5)
+		$(cmake-utils_use_find_package X XCB)
+	)
+
+	kde5_src_configure
+}