kde-frameworks: Add KDE Frameworks 5.61.0

Package-Manager: Portage-2.3.70, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 54 insertions, 0 deletions

diff --git a/kde-frameworks/frameworkintegration/Manifest b/kde-frameworks/frameworkintegration/Manifest
new file mode 100644
index 00000000000..29c5f2d8cd5
--- /dev/null
+++ b/kde-frameworks/frameworkintegration/Manifest
@@ -0,0 +1 @@
+DIST frameworkintegration-5.61.0.tar.xz 1753264 BLAKE2B 3db63e29c65ed49df7140f9cc058044ff9f78ee12221447843d5d5b1b6d4063d18f3c099221788af35ee6dd946a22fb43a265370561cbadff2476c4b97adf692 SHA512 9781e1d977713b2c7e604a30bb35a53e33f85002755d03615d501db101ac7ce718fcd50a83510f17806462998ddc11a88d38083d43a8a645643010ed17b06057
diff --git a/kde-frameworks/frameworkintegration/frameworkintegration-5.61.0.ebuild b/kde-frameworks/frameworkintegration/frameworkintegration-5.61.0.ebuild
new file mode 100644
index 00000000000..abb6426a7b4
--- /dev/null
+++ b/kde-frameworks/frameworkintegration/frameworkintegration-5.61.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_QTHELP="false"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Framework for integrating Qt applications with KDE Plasma workspaces"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="appstream X"
+
+DEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	appstream? (
+		app-admin/packagekit-qt
+		dev-libs/appstream[qt5]
+	)
+	X? (
+		$(add_qt_dep qtx11extras)
+		x11-libs/libxcb
+	)
+"
+RDEPEND="${DEPEND}"
+
+# requires running kde environment
+RESTRICT+=" test"
+
+src_prepare() {
+	punt_bogus_dep Qt5 DBus
+	kde5_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package appstream AppStreamQt)
+		$(cmake-utils_use_find_package appstream packagekitqt5)
+		$(cmake-utils_use_find_package X XCB)
+	)
+
+	kde5_src_configure
+}