kde-frameworks/kauth: Move 9999 to 5.9999

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/kde-frameworks/kauth/kauth-5.9999.ebuild b/kde-frameworks/kauth/kauth-5.9999.ebuild
new file mode 100644
index 00000000000..5a0d04a6b50
--- /dev/null
+++ b/kde-frameworks/kauth/kauth-5.9999.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework to let applications perform actions as a privileged user"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS=""
+IUSE="+policykit"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	policykit? ( >=sys-auth/polkit-qt-0.113.0[qt5(+)] )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+PDEPEND="policykit? ( kde-plasma/polkit-kde-agent )"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package policykit PolkitQt5-1)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# KAuthHelperTest test fails, bug 654842
+	local myctestargs=(
+		-E "(KAuthHelperTest)"
+	)
+
+	ecm_src_test
+}