kde-frameworks/kcrash: 5.100.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/kde-frameworks/kcrash/kcrash-5.100.0.ebuild b/kde-frameworks/kcrash/kcrash-5.100.0.ebuild
new file mode 100644
index 00000000000..bc93f71a3c3
--- /dev/null
+++ b/kde-frameworks/kcrash/kcrash-5.100.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for intercepting and handling application crashes"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="nls X"
+
+# requires running Plasma environment
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	test? ( >=dev-qt/qtwidgets-${QTMIN}:5 )
+"
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_X11=$(usex X)
+	)
+	ecm_src_configure
+}