kde-frameworks/kfilemetadata: 5.72.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
new file mode 100644
index 00000000000..c70e4af8ea0
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -0,0 +1 @@
+DIST kfilemetadata-5.72.0.tar.xz 425896 BLAKE2B 764909ce437d5cb6ed1f6c6fd4ec2ab3f4ab4a7f2ec6718436418396ed546fd53c867e8108af0ad5bd36edfcad5b7e39ef22631bc4f4868e653c241a57ab7ae1 SHA512 6f1c8dad61428b32c3aaabdc6f178fec07c96fd831c9e4b2be92130258241ea6d51c4ff6c0f3e42d22bd29b1b8fbf742e12725e6ec4229b9e59ad18f68e7ce7d
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.72.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.72.0.ebuild
new file mode 100644
index 00000000000..c47539a481c
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.72.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.14.2
+inherit ecm kde.org python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux office pdf taglib"
+
+BDEPEND="
+	test? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	office? ( =kde-frameworks/karchive-${PVCUT}*:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package office KF5Archive)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+		elog "To get additional features, optional runtime dependencies may be installed:"
+		elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+		elog "dev-libs/libxls - indexing of Microsoft Excel files"
+	fi
+}