kde-frameworks: Add KDE Frameworks 5.71.0

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
new file mode 100644
index 00000000000..d3d1d7f9167
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -0,0 +1 @@
+DIST kfilemetadata-5.71.0.tar.xz 425052 BLAKE2B 865307a16688bd6ed7b5195e227710c7a462489e8ac63cc79613b1afb3b7c623978483f1f4a619d3a66dfda0878c9cf4cebc4ba4e0a7c569d05122304f4de8c8 SHA512 df2e0252786bc4e43712e8e89e18ac426aaf1b2a6726042041176950fe5ff1f48bd7c1a07718651429cb8e7fc2907b620e8f2ecd3d298b8b9bfbce72dda24863
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.71.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.71.0.ebuild
new file mode 100644
index 00000000000..63201f961d0
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.71.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.14.1
+inherit ecm kde.org python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux office pdf taglib"
+
+BDEPEND="
+	test? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	office? ( =kde-frameworks/karchive-${PVCUT}*:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package office KF5Archive)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+		elog "To get additional features, optional runtime dependencies may be installed:"
+		elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+		elog "dev-libs/libxls - indexing of Microsoft Excel files"
+	fi
+}