kde-misc/kdeconnect: 22.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/kde-misc/kdeconnect/Manifest b/kde-misc/kdeconnect/Manifest
new file mode 100644
index 00000000000..2722effdc9f
--- /dev/null
+++ b/kde-misc/kdeconnect/Manifest
@@ -0,0 +1 @@
+DIST kdeconnect-kde-22.08.2.tar.xz 624328 BLAKE2B beaf0f5ea272f9d9197cdbe2d8278a324f555e437525ca1fdb0283ce53243ccef298e59c3fbabac2ac68e8f5f03cbb623dafe82d6363c06770b81d176d27751b SHA512 45f38a6704c3d57cbb8e1d87eea3ee0d3da0b438e6f2ce156ad0de5c64743d4e3b95c0695419c2d6acfcdd26813d5775be27a7c11ba4bf367a7e7940ba6b4bf0
diff --git a/kde-misc/kdeconnect/kdeconnect-22.08.2.ebuild b/kde-misc/kdeconnect/kdeconnect-22.08.2.ebuild
new file mode 100644
index 00000000000..ea42cf75c7c
--- /dev/null
+++ b/kde-misc/kdeconnect/kdeconnect-22.08.2.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KDE_ORG_NAME="${PN}-kde"
+KDE_SELINUX_MODULE="${PN}"
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Adds communication between KDE Plasma and your smartphone"
+HOMEPAGE="https://kdeconnect.kde.org/ https://apps.kde.org/kdeconnect/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="bluetooth pulseaudio X"
+
+RESTRICT="test"
+
+DEPEND="
+	>=app-crypt/qca-2.3.0:2[ssl]
+	>=dev-libs/wayland-1.15.0
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5=
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpeople-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	bluetooth? ( >=dev-qt/qtbluetooth-${QTMIN}:5 )
+	X? (
+		x11-libs/libfakekey
+		x11-libs/libX11
+		x11-libs/libXtst
+	)
+	pulseaudio? ( media-libs/pulseaudio-qt:= )
+"
+RDEPEND="${DEPEND}
+	dev-libs/kpeoplevcard
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5[qml]
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	net-fs/sshfs
+"
+BDEPEND="
+	dev-libs/plasma-wayland-protocols
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.07.80-revert-disable-kpeople.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBLUETOOTH_ENABLED=$(usex bluetooth)
+		$(cmake_use_find_package pulseaudio KF5PulseAudioQt)
+		$(cmake_use_find_package X LibFakeKey)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	elog "The Android .apk file is available via"
+	elog "https://play.google.com/store/apps/details?id=org.kde.kdeconnect_tp"
+	elog "or via"
+	elog "https://f-droid.org/packages/org.kde.kdeconnect_tp/"
+}