kde-plasma/kde-cli-tools: 5.21.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-plasma/kde-cli-tools/Manifest b/kde-plasma/kde-cli-tools/Manifest
index d01214a9bb9..52f6aba2a49 100644
--- a/kde-plasma/kde-cli-tools/Manifest
+++ b/kde-plasma/kde-cli-tools/Manifest
@@ -1 +1,2 @@
 DIST kde-cli-tools-5.20.90.tar.xz 611288 BLAKE2B 9551ed3ae7759016d750f1c2324f7a016e37a3964376839d57a6518f69e20e302f42bd09cc10a31d5abeec05e5b91e00d3696fddf8477c52c0bed6f19532ab8e SHA512 dcf18a4537c4d8592d952d634be4a18c1c43a37d146b42d344acc82500b321b9886a9cc6e9916a079b2c2718f79e503a89cc1aadb0d0d7f6d0384fd71fcdf774
+DIST kde-cli-tools-5.21.0.tar.xz 610328 BLAKE2B 23414a157f63227e68ac16551b6085e583467c54d85a6cd1a63f8cd37fb3b40f9da0d24683b6bf481d6687dc4da952cf78a6567a575fc7bc53f2f6c7cd05c753 SHA512 0c580b245e152f878f00d13c202707fec5566ac0101a580a53e0b39a5624aa8e6f2a343147b53af7f54fb496926adea2028eaeedc8b671bc8f76e661bf4ebb2d
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.21.0.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.21.0.ebuild
new file mode 100644
index 00000000000..d7a9e675956
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.21.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.78.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://invent.kde.org/plasma/kde-cli-tools"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="kdesu X"
+
+REQUIRED_USE="kdesu? ( X )"
+# requires running kde environment
+RESTRICT+=" test"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	kdesu? ( >=kde-frameworks/kdesu-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( sys-apps/dbus[X] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.12.80-tests-optional.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kdesu KF5Su)
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	use kdesu && dosym ../$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu
+}