kde-plasma/kde-cli-tools: 5.26.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-plasma/kde-cli-tools/Manifest b/kde-plasma/kde-cli-tools/Manifest
index 689300640c9..532c05b80e9 100644
--- a/kde-plasma/kde-cli-tools/Manifest
+++ b/kde-plasma/kde-cli-tools/Manifest
@@ -1 +1,2 @@
 DIST kde-cli-tools-5.25.90.tar.xz 630324 BLAKE2B a9ffa963efec5f4515953b91797e307d46ae8c0395f1552e4d84c21975a23f8accf53d79b04dd812e8bf745756ce8562f02f3f68857f9806c95a17f13efb13e1 SHA512 1283b76f81db2eff8225f4c44af185cd2553dbbea412afe3ee44a2540a4b8e6edcb685878b5fa2fde310ce93c65b0971823fa7a2da178ba731000dbafb0b5fb7
+DIST kde-cli-tools-5.26.0.tar.xz 630316 BLAKE2B ed1415de5f2f839860573df09763aa671ec50bfa74e7848ee6252260c8cba95dd4cce0ab3fd916bebf88079dd492d67f9b183c624035f2c453a516b5943f2b5a SHA512 92970b3b254e6489d99f0f1c0d4718fb17cf4973b9ab21848d666511431db1c5d54a0d9763e75e68518e741ece62cfd4192c211ca3736a553d43bfaf2d0b692f
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.26.0.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.26.0.ebuild
new file mode 100644
index 00000000000..b3abc2f9e67
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.26.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.98.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://invent.kde.org/plasma/kde-cli-tools"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="kdesu X"
+
+REQUIRED_USE="kdesu? ( X )"
+# requires running kde environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	kdesu? ( >=kde-frameworks/kdesu-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( sys-apps/dbus[X] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.12.80-tests-optional.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kdesu KF5Su)
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	use kdesu && dosym ../$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu
+}