kde-plasma/kde-cli-tools: 5.27.9 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-plasma/kde-cli-tools/Manifest b/kde-plasma/kde-cli-tools/Manifest
new file mode 100644
index 00000000000..e8277282a5b
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/Manifest
@@ -0,0 +1 @@
+DIST kde-cli-tools-5.27.9.tar.xz 667364 BLAKE2B 7b8dc995d901bdfbea6f27b871d52b1687d2fee11509ac8622d5a2b1e16263776d1be7be106efe087ca0baab1bf3c4e001c40adca3cb4ea2c6ba08a20c527213 SHA512 ff625bda336df1ffa8d093cf2408512d31dcba72c501d1b31f4bd806de96f17e6451f19c70e6a86d55b06115094708a3fcf1527b112f39175e24a74e6b160ab4
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.27.9.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.27.9.ebuild
new file mode 100644
index 00000000000..f9cbc6d999a
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.27.9.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://invent.kde.org/plasma/kde-cli-tools"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="kdesu X"
+
+REQUIRED_USE="kdesu? ( X )"
+# requires running kde environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kactivities-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/libkworkspace-${PVCUT}:5
+	kdesu? ( >=kde-frameworks/kdesu-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( sys-apps/dbus[X] )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-5.12.80-tests-optional.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kdesu KF5Su)
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	use kdesu && dosym ../$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu
+}