kde-plasma/kscreenlocker: 5.27.9 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/kde-plasma/kscreenlocker/Manifest b/kde-plasma/kscreenlocker/Manifest
new file mode 100644
index 00000000000..e586f16d4c1
--- /dev/null
+++ b/kde-plasma/kscreenlocker/Manifest
@@ -0,0 +1 @@
+DIST kscreenlocker-5.27.9.tar.xz 161040 BLAKE2B f5e1e4d1f3deed146a0412625439e0fab3e4264d6781d14e267f2776b4f056b71e43211bb9d8d05fb5267e22b73e3dd11cfbffd0d858dfd98f06302925a40143 SHA512 5447432c0a712c50c4f5429fef645ac19ed56fcefc0f4f8b5a2df55b62e5e802941975ae18c83db3d6e942e9edff663774be6d76ff06a5b4f10beebcffebeadf
diff --git a/kde-plasma/kscreenlocker/kscreenlocker-5.27.9.ebuild b/kde-plasma/kscreenlocker/kscreenlocker-5.27.9.ebuild
new file mode 100644
index 00000000000..24fa9b5ccf3
--- /dev/null
+++ b/kde-plasma/kscreenlocker/kscreenlocker-5.27.9.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org pam
+
+DESCRIPTION="Library and components for secure lock screen architecture"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RESTRICT="test"
+
+COMMON_DEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5[qml]
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/layer-shell-qt-${PVCUT}:5
+	>=kde-plasma/libkscreen-${PVCUT}:5
+	sys-libs/pam
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+BDEPEND="
+	dev-util/wayland-scanner
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+"
+PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:5"
+
+src_prepare() {
+	ecm_src_prepare
+	use test || cmake_run_in greeter cmake_comment_add_subdirectory autotests
+}
+
+src_test() {
+	# requires running environment
+	local myctestargs=(
+		-E x11LockerTest
+	)
+	ecm_src_test
+}
+
+src_install() {
+	ecm_src_install
+
+	newpamd "${FILESDIR}/kde.pam" kde
+	newpamd "${FILESDIR}/kde-np.pam" kde-np
+}