Merge updates from master

4 files changed, 293 insertions, 3 deletions

diff --git a/kde-plasma/kwin/Manifest b/kde-plasma/kwin/Manifest
new file mode 100644
index 00000000000..ecdf08b2ef9
--- /dev/null
+++ b/kde-plasma/kwin/Manifest
@@ -0,0 +1 @@
+DIST kwin-6.4.90.tar.xz 8779592 BLAKE2B 474f16c603a0d909cc2631121474709d9fa593eff31cabdf3e92adea6f2746e6a98f20024fb2a7f71f8cecdd2cfd7bc681124eefd1498de511df1efb3fe40cc0 SHA512 f41d58faf0c14e9cc8a193d8d9916c84fd4abcc0fb0fee3a427667672b72ec46620b98d99182739492278d87bae8f847d3a9cc4d9cd90cca3a392e5fa70c71b6
diff --git a/kde-plasma/kwin/kwin-6.4.90.ebuild b/kde-plasma/kwin/kwin-6.4.90.ebuild
new file mode 100644
index 00000000000..c389556fe2c
--- /dev/null
+++ b/kde-plasma/kwin/kwin-6.4.90.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+# TODO: ECMGenerateQDoc
+ECM_TEST="true"
+KFMIN=6.18.0
+QTMIN=6.9.1
+inherit ecm fcaps plasma.kde.org xdg
+
+DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="accessibility gles2-only lock screencast +shortcuts systemd X"
+
+RESTRICT="test"
+
+# qtbase slot op: GuiPrivate use in tabbox, Qt6WaylandClientPrivate for xx-pip-v1
+# qtbase[X]: private/qtx11extras_p.h in src/helpers/killer
+COMMON_DEPEND="
+	dev-libs/libei
+	>=dev-libs/libinput-1.27:=
+	>=dev-libs/wayland-1.24.0
+	>=dev-qt/qt5compat-${QTMIN}:6[qml]
+	>=dev-qt/qtbase-${QTMIN}:6=[accessibility=,gles2-only=,gui,libinput,opengl,wayland,widgets,X]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=dev-qt/qtsensors-${QTMIN}:6
+	>=dev-qt/qtshadertools-${QTMIN}:6
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=dev-qt/qttools-${QTMIN}:6[widgets]
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6[qml]
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdeclarative-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6[wayland]
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6=[wayland]
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kpackage-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ksvg-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6=[wayland]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-plasma/kdecoration-${KDE_CATV}:6
+	>=kde-plasma/knighttime-${KDE_CATV}:6
+	>=kde-plasma/kwayland-${KDE_CATV}:6
+	>=kde-plasma/plasma-activities-${KDE_CATV}:6
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/lcms:2
+	media-libs/libcanberra
+	>=media-libs/libdisplay-info-0.2.0:=
+	media-libs/libepoxy
+	media-libs/libglvnd
+	>=media-libs/mesa-24.1.0_rc1[opengl,wayland]
+	virtual/libudev:=
+	>=x11-libs/libdrm-2.4.118
+	>=x11-libs/libxcb-1.10:=
+	>=x11-libs/libxcvt-0.1.1
+	>=x11-libs/libxkbcommon-1.5.0
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-wm
+	accessibility? ( media-libs/libqaccessibilityclient:6 )
+	lock? ( >=kde-plasma/kscreenlocker-${KDE_CATV}:6 )
+	screencast? ( >=media-video/pipewire-1.2.0:= )
+	shortcuts? ( >=kde-plasma/kglobalacceld-${KDE_CATV}:6 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXi
+		x11-libs/libXres
+		x11-libs/xcb-util-keysyms
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-plasma/kdeplasma-addons:5
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-plasma/aurorae-${KDE_CATV}:6
+	>=kde-plasma/breeze-${KDE_CATV}:6
+	>=kde-plasma/libplasma-${KDE_CATV}:6
+	sys-apps/hwdata
+	X? ( >=x11-base/xwayland-23.1.0[libei] )
+"
+RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/plasma-wayland-protocols-1.19.0
+	>=dev-libs/wayland-protocols-1.45
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+	test? ( screencast? ( >=kde-plasma/kpipewire-${KDE_CATV}:6 ) )
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[wayland]
+	dev-util/wayland-scanner
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+"
+BDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
+
+# https://bugs.gentoo.org/941628
+# -m 0755 to avoid suid with USE="-filecaps"
+FILECAPS=( -m 0755 cap_sys_nice=ep usr/bin/kwin_wayland )
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use screencast; then
+		sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if ! use systemd; then
+		sed -e "s/^pkg_check_modules.*libsystemd/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# KWIN_BUILD_DECORATIONS exists, drops aurorae, breeze
+		# KWIN_BUILD_NOTIFICATIONS exists, but kdeclarative still hard-depends on it
+		$(cmake_use_find_package accessibility QAccessibilityClient6)
+		-DKWIN_BUILD_SCREENLOCKER=$(usex lock)
+		-DKWIN_BUILD_GLOBALSHORTCUTS=$(usex shortcuts)
+		-DKWIN_BUILD_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	fcaps_pkg_postinst
+}
diff --git a/kde-plasma/kwin/kwin-6.5.49.9999.ebuild b/kde-plasma/kwin/kwin-6.5.49.9999.ebuild
new file mode 100644
index 00000000000..0188d799b80
--- /dev/null
+++ b/kde-plasma/kwin/kwin-6.5.49.9999.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+# TODO: ECMGenerateQDoc
+ECM_TEST="true"
+KFMIN=6.18.0
+QTMIN=6.9.1
+inherit ecm fcaps plasma.kde.org xdg
+
+DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS=""
+IUSE="accessibility gles2-only lock screencast +shortcuts systemd X"
+
+RESTRICT="test"
+
+# qtbase slot op: GuiPrivate use in tabbox, Qt6WaylandClientPrivate for xx-pip-v1
+# qtbase[X]: private/qtx11extras_p.h in src/helpers/killer
+COMMON_DEPEND="
+	dev-libs/libei
+	>=dev-libs/libinput-1.27:=
+	>=dev-libs/wayland-1.24.0
+	>=dev-qt/qt5compat-${QTMIN}:6[qml]
+	>=dev-qt/qtbase-${QTMIN}:6=[accessibility=,gles2-only=,gui,libinput,opengl,wayland,widgets,X]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=dev-qt/qtsensors-${QTMIN}:6
+	>=dev-qt/qtshadertools-${QTMIN}:6
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=dev-qt/qttools-${QTMIN}:6[widgets]
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6[qml]
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdeclarative-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6[wayland]
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6=[wayland]
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kpackage-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ksvg-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6=[wayland]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-plasma/kdecoration-${KDE_CATV}:6
+	>=kde-plasma/knighttime-${KDE_CATV}:6
+	>=kde-plasma/kwayland-${KDE_CATV}:6
+	>=kde-plasma/plasma-activities-${KDE_CATV}:6
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/lcms:2
+	media-libs/libcanberra
+	>=media-libs/libdisplay-info-0.2.0:=
+	media-libs/libepoxy
+	media-libs/libglvnd
+	>=media-libs/mesa-24.1.0_rc1[opengl,wayland]
+	virtual/libudev:=
+	>=x11-libs/libdrm-2.4.118
+	>=x11-libs/libxcb-1.10:=
+	>=x11-libs/libxcvt-0.1.1
+	>=x11-libs/libxkbcommon-1.5.0
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-wm
+	accessibility? ( media-libs/libqaccessibilityclient:6 )
+	lock? ( >=kde-plasma/kscreenlocker-${KDE_CATV}:6 )
+	screencast? ( >=media-video/pipewire-1.2.0:= )
+	shortcuts? ( >=kde-plasma/kglobalacceld-${KDE_CATV}:6 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXi
+		x11-libs/libXres
+		x11-libs/xcb-util-keysyms
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-plasma/kdeplasma-addons:5
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-plasma/aurorae-${KDE_CATV}:6
+	>=kde-plasma/breeze-${KDE_CATV}:6
+	>=kde-plasma/libplasma-${KDE_CATV}:6
+	sys-apps/hwdata
+	X? ( >=x11-base/xwayland-23.1.0[libei] )
+"
+RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/plasma-wayland-protocols-1.19.0
+	>=dev-libs/wayland-protocols-1.45
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+	test? ( screencast? ( >=kde-plasma/kpipewire-${KDE_CATV}:6 ) )
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[wayland]
+	dev-util/wayland-scanner
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+"
+BDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
+
+# https://bugs.gentoo.org/941628
+# -m 0755 to avoid suid with USE="-filecaps"
+FILECAPS=( -m 0755 cap_sys_nice=ep usr/bin/kwin_wayland )
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use screencast; then
+		sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
+	fi
+
+	# TODO: try to get a build switch upstreamed
+	if ! use systemd; then
+		sed -e "s/^pkg_check_modules.*libsystemd/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# KWIN_BUILD_DECORATIONS exists, drops aurorae, breeze
+		# KWIN_BUILD_NOTIFICATIONS exists, but kdeclarative still hard-depends on it
+		$(cmake_use_find_package accessibility QAccessibilityClient6)
+		-DKWIN_BUILD_SCREENLOCKER=$(usex lock)
+		-DKWIN_BUILD_GLOBALSHORTCUTS=$(usex shortcuts)
+		-DKWIN_BUILD_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	fcaps_pkg_postinst
+}
diff --git a/kde-plasma/kwin/kwin-9999.ebuild b/kde-plasma/kwin/kwin-9999.ebuild
index 1c9b5cdb049..dbfefc925fb 100644
--- a/kde-plasma/kwin/kwin-9999.ebuild
+++ b/kde-plasma/kwin/kwin-9999.ebuild
@@ -4,6 +4,7 @@
 EAPI=8
 
 ECM_HANDBOOK="optional"
+# TODO: ECMGenerateQDoc
 ECM_TEST="true"
 KFMIN=9999
 QTMIN=6.9.1
@@ -18,7 +19,7 @@ IUSE="accessibility gles2-only lock screencast +shortcuts systemd X"
 
 RESTRICT="test"
 
-# qtbase slot op: GuiPrivate use in tabbox
+# qtbase slot op: GuiPrivate use in tabbox, Qt6WaylandClientPrivate for xx-pip-v1
 # qtbase[X]: private/qtx11extras_p.h in src/helpers/killer
 COMMON_DEPEND="
 	dev-libs/libei
@@ -93,7 +94,7 @@ RDEPEND="${COMMON_DEPEND}
 "
 RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
 DEPEND="${COMMON_DEPEND}
-	>=dev-libs/plasma-wayland-protocols-1.18.0
+	>=dev-libs/plasma-wayland-protocols-1.19.0
 	>=dev-libs/wayland-protocols-1.45
 	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
 	test? ( screencast? ( >=kde-plasma/kpipewire-${KDE_CATV}:6 ) )
@@ -126,7 +127,7 @@ src_prepare() {
 
 src_configure() {
 	local mycmakeargs=(
-		# KWIN_BUILD_DECORATIONS exists
+		# KWIN_BUILD_DECORATIONS exists, drops aurorae, breeze
 		# KWIN_BUILD_NOTIFICATIONS exists, but kdeclarative still hard-depends on it
 		$(cmake_use_find_package accessibility QAccessibilityClient6)
 		-DKWIN_BUILD_SCREENLOCKER=$(usex lock)