kde-plasma/libkworkspace: 5.24.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/kde-plasma/libkworkspace/Manifest b/kde-plasma/libkworkspace/Manifest
new file mode 100644
index 00000000000..ef6ebf4331f
--- /dev/null
+++ b/kde-plasma/libkworkspace/Manifest
@@ -0,0 +1 @@
+DIST plasma-workspace-5.24.0.tar.xz 18453948 BLAKE2B d744b63baac3cb2704679de509bd841a74915537f51bad3fe0936487883e9c01645736e79ca1fb5171a23a28897830d16e263f71646a237a9b512f1483ef83c8 SHA512 85686c93ca867b5ae04afc5c93775c9821739badf33a340c90862b8cbc64e878fcb94ad673fc8770692321e77759a6ef1d5c7738207b650a3af1d5d96c0a5485
diff --git a/kde-plasma/libkworkspace/libkworkspace-5.24.0.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.24.0.ebuild
new file mode 100644
index 00000000000..7b3149edc1d
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.24.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KDE_ORG_NAME="plasma-workspace"
+KFMIN=5.90.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kscreenlocker-${PVCUT}:5
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-plasma/kwin-${PVCUT}:5
+"
+
+S="${S}/${PN}"
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+		rm -rf po/*/docs || die
+		cp -a ../po ./ || die
+	fi
+
+	eapply "${FILESDIR}/${PN}-5.22.80-standalone.patch"
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" -i CMakeLists.txt || die
+	cat >> CMakeLists.txt <<- _EOF_ || die
+		ki18n_install(po)
+	_EOF_
+
+	ecm_src_prepare
+}