kde-plasma/libplasma: 5.114.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/kde-plasma/libplasma/Manifest b/kde-plasma/libplasma/Manifest
new file mode 100644
index 00000000000..c886c732ed4
--- /dev/null
+++ b/kde-plasma/libplasma/Manifest
@@ -0,0 +1 @@
+DIST plasma-framework-5.114.0.tar.xz 3308372 BLAKE2B 00c3115d4041c34d123676cf67ed0d3738ef2633931d47619497abb0dc03c267e6ce47dfae127bd9eabe2ddb681b594bbfd8e2cf4a81f02f3c4d753a8d79a190 SHA512 bd67a64a5d6e8b37cbdfe4bb6879987a3eccd39e71fa08753f9044f03652be5b4eeb3204de51695f15a32ba8a552b804261177eec564fb41c89a39af83122f24
diff --git a/kde-plasma/libplasma/libplasma-5.114.0.ebuild b/kde-plasma/libplasma/libplasma-5.114.0.ebuild
new file mode 100644
index 00000000000..987b3ba7565
--- /dev/null
+++ b/kde-plasma/libplasma/libplasma-5.114.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_NONGUI="true"
+ECM_QTHELP="true"
+ECM_TEST="true"
+KDE_ORG_TAR_PN="plasma-framework"
+KFMIN=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Plasma library and runtime components based upon KF5 and Qt5"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gles2-only kf6compat man wayland"
+
+RESTRICT="test"
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=,X]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	=kde-frameworks/karchive-${KFMIN}*:5
+	=kde-frameworks/kconfig-${KFMIN}*:5[qml]
+	=kde-frameworks/kconfigwidgets-${KFMIN}*:5
+	=kde-frameworks/kcoreaddons-${KFMIN}*:5
+	=kde-frameworks/kdeclarative-${KFMIN}*:5
+	=kde-frameworks/kglobalaccel-${KFMIN}*:5
+	=kde-frameworks/kguiaddons-${KFMIN}*:5
+	=kde-frameworks/ki18n-${KFMIN}*:5
+	=kde-frameworks/kiconthemes-${KFMIN}*:5
+	=kde-frameworks/kio-${KFMIN}*:5
+	=kde-frameworks/kirigami-${KFMIN}*:5
+	=kde-frameworks/knotifications-${KFMIN}*:5
+	=kde-frameworks/kpackage-${KFMIN}*:5
+	=kde-frameworks/kservice-${KFMIN}*:5
+	=kde-frameworks/kwidgetsaddons-${KFMIN}*:5
+	=kde-frameworks/kwindowsystem-${KFMIN}*:5[X]
+	=kde-frameworks/kxmlgui-${KFMIN}*:5
+	=kde-plasma/plasma-activities-${KFMIN}*:5
+	x11-libs/libX11
+	x11-libs/libxcb
+	!gles2-only? ( media-libs/libglvnd[X] )
+	wayland? (
+		=kde-plasma/kwayland-${KFMIN}*:5
+		media-libs/libglvnd
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	kf6compat? ( kde-plasma/libplasma:6 )
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${KFMIN}:5 )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DESKTOPTHEMES=$(usex !kf6compat)
+		$(cmake_use_find_package !gles2-only OpenGL)
+		$(cmake_use_find_package man KF5DocTools)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+	)
+
+	ecm_src_configure
+}