kde-plasma/powerdevil: drop 6.2.49.9999

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 0 insertions, 94 deletions

diff --git a/kde-plasma/powerdevil/powerdevil-6.2.49.9999.ebuild b/kde-plasma/powerdevil/powerdevil-6.2.49.9999.ebuild
deleted file mode 100644
index dde3f2a2669..00000000000
--- a/kde-plasma/powerdevil/powerdevil-6.2.49.9999.ebuild
+++ /dev/null
@@ -1,94 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-KFMIN=6.6.0
-QTMIN=6.7.2
-inherit ecm fcaps plasma.kde.org
-
-DESCRIPTION="Power management for KDE Plasma Shell"
-HOMEPAGE="https://invent.kde.org/plasma/powerdevil"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS=""
-IUSE="brightness-control"
-
-RESTRICT="test" # bug 926513
-
-# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
-COMMON_DEPEND="
-	dev-libs/qcoro[dbus]
-	dev-libs/wayland
-	>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets]
-	>=dev-qt/qtwayland-${QTMIN}:6=
-	>=kde-frameworks/kauth-${KFMIN}:6[policykit]
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/kdbusaddons-${KFMIN}:6
-	>=kde-frameworks/kglobalaccel-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kidletime-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/kirigami-${KFMIN}:6
-	>=kde-frameworks/kitemmodels-${KFMIN}:6
-	>=kde-frameworks/knotifications-${KFMIN}:6
-	>=kde-frameworks/krunner-${KFMIN}:6
-	>=kde-frameworks/kservice-${KFMIN}:6
-	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	>=kde-frameworks/solid-${KFMIN}:6
-	>=kde-plasma/libkscreen-${KDE_CATV}:6
-	>=kde-plasma/libplasma-${KDE_CATV}:6
-	>=kde-plasma/plasma-activities-${KDE_CATV}:6
-	>=kde-plasma/plasma-workspace-${KDE_CATV}:6
-	virtual/libudev:=
-	x11-libs/libxcb
-	brightness-control? ( app-misc/ddcutil:= )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/plasma-wayland-protocols-1.14.0
-"
-RDEPEND="${COMMON_DEPEND}
-	!<kde-plasma/plasma-workspace-6.1.90:*
-	>=dev-qt/qtdeclarative-${QTMIN}:6
-	|| (
-		sys-power/power-profiles-daemon
-		sys-power/tlp
-	)
-	>=sys-power/upower-0.9.23
-"
-BDEPEND="
-	>=dev-qt/qtwayland-${QTMIN}:6
-	>=kde-frameworks/kcmutils-${KFMIN}:6
-"
-
-# -m 0755 to avoid suid with USE="-filecaps"
-FILECAPS=( -m 0755 cap_sys_nice=ep usr/libexec/org_kde_powerdevil )
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_Libcap=ON
-		$(cmake_use_find_package brightness-control DDCUtil)
-	)
-	use test && mycmakeargs+=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # not packaged
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	# bug 926513
-	ecm_src_test -j1
-}
-
-pkg_postinst() {
-	ecm_pkg_postinst
-	fcaps_pkg_postinst
-}