net-irc/konversation: 22.11.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/net-irc/konversation/Manifest b/net-irc/konversation/Manifest
new file mode 100644
index 00000000000..73c0dcb692a
--- /dev/null
+++ b/net-irc/konversation/Manifest
@@ -0,0 +1 @@
+DIST konversation-22.11.80.tar.xz 4433208 BLAKE2B 10dd9e2bc9df3cf4297e76612b2c3f1d721ece667e5df79d3fce63b4912f2c0bb60ea051fd7f287233f6332dd55fbb492639cf7d567bb7ceb870330bacc6b353 SHA512 2fd8ef09b9d31e33feaf78ffad3652e417a12c0325ac24a8875b5d453e355c92df1855aa6dc26b8dbadbe571139b07cd67e54f265467dce40bb9e9aaad956c2b
diff --git a/net-irc/konversation/konversation-22.11.80.ebuild b/net-irc/konversation/konversation-22.11.80.ebuild
new file mode 100644
index 00000000000..93966595e8f
--- /dev/null
+++ b/net-irc/konversation/konversation-22.11.80.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.98.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="User friendly IRC Client"
+HOMEPAGE="https://konversation.kde.org https://apps.kde.org/konversation/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+crypt"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[qt5(+)] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[qt5(+),ssl] )
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Qca-qt5)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# Bug 616162
+	insinto /etc/xdg
+	doins "${FILESDIR}"/konversationrc
+}