2 files changed, 54 insertions, 0 deletions
diff --git a/kde-frameworks/kirigami/Manifest b/kde-frameworks/kirigami/Manifest
new file mode 100644
index 00000000000..c8203fdb1cb
--- /dev/null
+++ b/kde-frameworks/kirigami/Manifest
@@ -0,0 +1 @@
+DIST kirigami2-5.103.0.tar.xz 372552 BLAKE2B 707912f6201d6f5a5e259304de913dac4d5d82ccd18333e4d4707da94692354d25bcf0977d04cb979903e27d6d8c0b453e14f93e3313a0d10ba9b7cfd3332934 SHA512 1b70342cbaa1ca2c2391c3f0b31a9c24150eb1a7c3540c66eab2655c56f900d047a0355a56a1edafe7e05280eee027a3fde13b7dcd6a2913c1d91330a0e39533
diff --git a/kde-frameworks/kirigami/kirigami-5.103.0.ebuild b/kde-frameworks/kirigami/kirigami-5.103.0.ebuild
new file mode 100644
index 00000000000..b728e7fee01
--- /dev/null
+++ b/kde-frameworks/kirigami/kirigami-5.103.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_EXAMPLES="true"
+ECM_QTHELP="false"
+ECM_TEST="true"
+KDE_ORG_NAME="${PN}2"
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org toolchain-funcs
+
+DESCRIPTION="Lightweight user interface framework for mobile and convergent applications"
+HOMEPAGE="https://techbase.kde.org/Kirigami"
+EGIT_REPO_URI="${EGIT_REPO_URI/${PN}2/${PN}}"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+openmp"
+
+# requires package to already be installed
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES=$(usex examples)
+		$(cmake_use_find_package openmp OpenMP)
+	)
+
+	ecm_src_configure
+}