2 files changed, 67 insertions, 0 deletions
diff --git a/kde-apps/dolphin-plugins-subversion/Manifest b/kde-apps/dolphin-plugins-subversion/Manifest
new file mode 100644
index 00000000000..07340894ead
--- /dev/null
+++ b/kde-apps/dolphin-plugins-subversion/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-20.07.80.tar.xz 224904 BLAKE2B d1a85c11331c97df147595e1c93c31b51203a3312d0b2731dffa00a2c866ed466b22afa3edbe13a2856e220db69bfe2a669ce6100e019da475c5d962fdf24eb1 SHA512 28d8d87da3fedb8add330b03cd0f243fd4da465f77a620dc96ad4e8656b04e0725869e9ec045590b3c761a48779b44cc2a8d86670bd223d031881d1064cab4f5
diff --git a/kde-apps/dolphin-plugins-subversion/dolphin-plugins-subversion-20.07.80.ebuild b/kde-apps/dolphin-plugins-subversion/dolphin-plugins-subversion-20.07.80.ebuild
new file mode 100644
index 00000000000..2bf6fd44a2d
--- /dev/null
+++ b/kde-apps/dolphin-plugins-subversion/dolphin-plugins-subversion-20.07.80.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="svn"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Subversion integration"
+HOMEPAGE="https://kde.org/applications/system/org.kde.dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-apps/dolphin-plugins:5
+	dev-vcs/subversion
+	>=kde-apps/kompare-${PVCUT}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}