2 files changed, 58 insertions, 0 deletions
diff --git a/kde-frameworks/kidletime/Manifest b/kde-frameworks/kidletime/Manifest
new file mode 100644
index 00000000000..05b57caf796
--- /dev/null
+++ b/kde-frameworks/kidletime/Manifest
@@ -0,0 +1 @@
+DIST kidletime-6.11.0.tar.xz 30764 BLAKE2B f8a07927ea59ebc64a96e2b322aae45fa1d74bc8e134b5ef94624be6e2098128e2baae66e1a0317176d39111cd0cc87ecd56cb14b848917b29949d58824294a8 SHA512 f7df3495032f608f597fe07cdd89a4e32645946a7ae1d597d6920e3ba45de0a42aab592b27d95ac4a8bec7c9ea7a2dc0c88a8d11198f27e68864e74096d9dd9a
diff --git a/kde-frameworks/kidletime/kidletime-6.11.0.ebuild b/kde-frameworks/kidletime/kidletime-6.11.0.ebuild
new file mode 100644
index 00000000000..5043bf338c2
--- /dev/null
+++ b/kde-frameworks/kidletime/kidletime-6.11.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtbase-${QTMIN}:6=[wayland]
+		>=dev-qt/qtwayland-${QTMIN}:6
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus]
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		>=dev-libs/plasma-wayland-protocols-1.11.1
+		>=dev-libs/wayland-protocols-1.27:0
+	)
+"
+BDEPEND="wayland? ( >=dev-qt/qtwayland-${QTMIN}:6 )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_WAYLAND=$(usex wayland)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}